HOME > 即効テクニック > AccessVBA > フォーム・レポート > 数レコードごとに太線を引く

即効テクニック

フォーム・レポート

数レコードごとに太線を引く

(Access 2000/2002/2003)
● 概要 ●
構文  expression.Line(Step(x1, y1)-Step(x2, y2), color, B/F)


設定項目        内容
expression	Reportオブジェクト[省略可能]
Step		対象となるオブジェクトのCurrentX/CurrentYプロパティの値を基	
		準として線の始点の座標値を指定する場合に記述するキーワード	
		[省略可能]
x1		線の始点のx座標を指定[省略不可]
y1		線の始点のy座標を指定[省略不可]
Step		線の始点の座標値を基準として終点の座標値を指定する場合に記述
		するキーワード[省略可能]
x2		線の終点のx座標を指定[省略不可]
y2		線の終点のy座標を指定[省略不可]
color		線の色を指定[省略可能]
B/F		長方形とするか、内側を塗りつぶすかをB/Fオプションで指定
		[省略可能]

数レコードごとに太線を引きます。レポートの詳細セクションに、テキストボックスを配置します。
テキストボックスのプロパティで、名前を「行番号」、コントロールソースを「=1」、可視を「いいえ」、集計実行を「全体」に設定します。
このテキストボックス「行番号」の値を利用して、線を引くレコードを判定し、Lineメソッドで線を引きます。
引数<x1>、<y1>に線の始点の座標、<x2>、<y2>に線の終点の座標を指定します。
引数<color>に線の色を指定します。オプション<B/F>にはBFと指定します。


● サンプル ●
Private Sub 詳細_Print(Cancel As Integer, PrintCount As Integer)
    '線の始点、終点のx座標、y座標を代入する変数を宣言
    Dim myStartX As Variant
    Dim myStartY As Variant
    Dim myEndX As Variant
    Dim myEndY As Variant
    '始点のx座標を指定
    myStartX = 0
    '始点のy座標を指定
    myStartY = Me.Section(acDetail).Height - 100
    '終点のx座標を指定
    myEndX = Me.Width
    '終点のy座標を指定
    myEndY = Me.Section(acDetail).Height
    '行番号が5で割り切れるとき、線を引く
    If Me.行番号 Mod 5 = 0 Then
        '線の位置を指定、色はオレンジ色、長方形として塗りつぶす、と指定
        Line (myStartX, myStartY)-(myEndX, myEndY), RGB(250, 150, 50), BF
    End If
End Sub