スキルアップ・問題解決なら、モーグにおまかせ！

こんばんは、よろしくお願いいたします。
以下の２列ごとのデータを１列にするには、どうしたらよいでしょうか？
クリップボードで２列ごとにコピーしてすべて貼り付けすると
実際はもっとたくさんあるので、途中のデータが抜けたりしてうまく
まとめられません。
よろしくお願いいたします(._.)ｍ
 
名前    年齢    名前    年齢    名前    年齢・・
田中    52    米田    15    遠藤    60
佐藤    18    飯島    45    宇野    25
遠藤    16    村田    20    江川    60
 
↓
            
                    
名前    年齢                
田中    52                
佐藤    18                
遠藤    16                
米田    15                
飯島    45                
村田    20                
遠藤    60                
宇野    25                
江川    60                
・
・

　　A　　B　　C　　D　　E　　F　　G
1　名前 年齢 名前 年齢 名前 年齢 名前
2　田中　 52 米田　 15 遠藤　 60 …
3　佐藤　 18 飯島　 45 宇野　 25 …
4　遠藤　 16 村田　 20 江川　 60 …
5　…　　 … …　　 … …　　 … …
6
7　名前 年齢　　 式 =OFFSET(A$2,MOD(ROW(A1)-1,3),2*INT((ROW(A1)-1)/3))
8　田中　 52　　 を入力したセル A8 を右隣り＆下方にズズーッとオートフィル
9　佐藤　 18　　 オ・シ・マ・イ
10 遠藤　 16
11 米田　 15
12 飯島　 45
13 村田　 20
14 遠藤　 60
15 宇野　 25
16 江川　 60
17 …　　 …

●Sheet1
 
　　　A　　 B　　 C　　 D　　 E　　 F
1　名前　年齢　名前　年齢　名前　年齢
2　田中　　52　米田　　15　遠藤　　60
3　佐藤　　18　飯島　　45　宇野　　25
4　遠藤　　16　　　　　　　江川　　60
5　村田　　20　　　　　　　　　　　　
 
●Sheet2
 
　　　 A　　 B　C　D
 1　名前　年齢　　　
 2　田中　　52　4　1
 3　佐藤　　18　6　1
 4　遠藤　　16　9　1
 5　村田　　20　　 1
 6　米田　　15　　 2
 7　飯島　　45　　 2
 8　遠藤　　60　　 3
 9　宇野　　25　　 3
10　江川　　60　　 3
 
C2
=IFERROR(C1+TEXT(COUNTA(INDEX(Sheet1!$2:$500,,2*ROW(C1)-1)),"0;;;"),"")
下方向・↓
D2
=IF(ROW(D1)>MAX($C:$C),"",XMATCH(ROW(D1),$C:$C,1,-1)-1)
下方向・↓
A2
=IF(D2="","",INDEX(Sheet1!$2:$500,COUNTIF(D$2:D2,D2),2*D2-1))
下方向・↓
B2
=IF(D2="","",INDEX(Sheet1!$2:$500,COUNTIF(D$2:D2,D2),2*D2))
下方向・↓

Mike様、んなっと様
 
いつもありがとうございます！
どちらの方法でもできました！
ありがとうございました( ´ー`)///