おかしい と すれば
参照先が違う
引用:
A2セルに数字を入力するコードを先端に入れています。
引用:
Range("A2").Value = frmPage
ここでは、アクティブシートの A2 に 代入
引用:
For i = 1 To Worksheets("1枚目").Range("A1").Value
ここでは、1枚目シートの A1 に代入。
シートに関しては、必ず 1 枚目シートが、アクティブシートになるのであれば問題ありませんが
セル A1、A2 では、参照先が違います。
以降、問題とはならないでしょうが、参考までに・・
・セルに値を代入するということは、セルの値を書き換えます。
「印刷だけ」を行うユーザーでも、ブックを閉じる時に 上書きしますか？ と問われる事になります。
セルに代入を行う必要があるか、検討ください。
・キャンセルと、何も入力しないでOK を ユーザーレベルの視点で見たとき分ける必要があるでしょうか？
なにも入れず OK の時は、再入力を求める制御を行う様な時には必要があると思いますが
今回の中では、分ける必要はないと思います。
色々な場合のエラーに対してもメッセージを出されているので、
ある程度の問題に対し、内部判定を行いメッセージを出すようなコードを参考に提示します。
正常な場合のみ 印刷を行い、不正な場合はメッセージなしで終了するなら
「ここから」-「ここまで」は不要でも良いでしょう。
(印刷対象シートの存在確認を行ってから印刷を行っています。
入力値に問題があれば、存在しているシートが、印刷対象にならないだけ。
これだと、ユーザーが入力に問題がある事に気づきづらいので
ステータスバー表示、終了時メッセージを追加しています)
Sub Sumple()
Dim frmPage As String
Dim strMessage As String
Dim i As Long
Dim wst As Worksheet
frmPage = InputBox("連番を挿入して印刷します" & Chr(13) & "終了番号「数字のみ」を入力してください")
’ここから------------------------------
If StrPtr(frmPage) = 0 Then
'キャンセル又は右上の×をクリックした場合
strMessage = "キャンセル、終了します。"
ElseIf frmPage = "0" Then
'なにも入力しないでOKをクリックした場合
strMessage = "0は無効です、終了します。"
ElseIf frmPage = "" Then
'なにも入力しないでOKをクリックした場合
strMessage = "未入力、終了します。"
ElseIf IsNumeric(frmPage) = False Then
'数字でない値が入力されてOKをクリックした場合
strMessage = "数字以外が入力されています、終了します。"
ElseIf Abs(frmPage) > 32767 Then
'桁数が大きすぎる数値が入力されてOKをクリックした場合
strMessage = "桁数が大きすぎる値が入力されています、終了します。"
ElseIf CInt(frmPage) <> frmPage Then
'小数点を含む値が入力されてOKをクリックした場合
strMessage = "小数点を含む数字が入力されています、終了します。"
ElseIf CInt(frmPage) < 0 Then
'負の値が入力されてOKをクリックした場合
strMessage = "負の整数が入力されています、終了します。"
End If
If strMessage = "" Then
MsgBox "続けます"
Else
MsgBox strMessage
Exit Sub
End If
’ここまで------------------------------
If IsNumeric(frmPage) Then
For i = 1 To CInt(frmPage)
For Each wst In ThisWorkbook.Worksheets
If wst.Name = i & "枚目" Then
Application.StatusBar = wst.Name & "印刷中"
wst.PrintOut
Application.StatusBar = False
Exit For
End If
Next wst
Next i
End If
MsgBox "終了します"
End Sub
