スキルアップ・問題解決なら、モーグにおまかせ！

こんばんは、最近、度々、よろしくお願いいたします(._.)
 
以下のように、とびとびに数値が20個位あります。
 
野菜　名前　個数　名前　個数　名前　個数・・・
なすび　田辺　７　宇野　5　中野　3
トマト　吉村　10　遠藤　6　
いちご　田中　6　内田　9　中村　7
トマト　山下　2　遠藤　５　吉村　6
・
・
 
これをもとに
 
なすび　17
トマト　29
いちご　22
と合計したくて
 
なすび　=SUM(FILTER(A2:G5,A2:A5=A8:A10))
トマト　
いちご　
 
と作成したのですが、エラー値になってしまいます。
FILTER関数では、A2:A5=A8と条件が1つしか指定できないのでしょうか・・
 
また、ブックを2019しか入っていない部署のパソコンでもひらけるように
=SUMPRODUCT((A2:A5=A8)*B2:G5)
と作成もしてみましたが、途中の列に文字列を含むので
こちらもえらーになってしまいます・・
この表の形のままで、野菜ごとに合計したいのですが
上記の数式をどう修正すればよいでしょうか・・
よろしくお願いします(._.
 
 
 
 
 
 
 
 
 

　　　　 A　　 B　　 C　　 D　　 E　　 F　　 G
 1　　野菜　名前　個数　名前　個数　名前　個数
 2　なすび　田辺　　 7　宇野　　 5　中野　　 3
 3　トマト　吉村　　10　遠藤　　 6　　　　　　
 4　いちご　田中　　 6　内田　　 9　中村　　 7
 5　トマト　山下　　 2　遠藤　　 5　吉村　　 6
 6　　　　　　　　　　　　　　　　　　　　　　
 7　　　　　　　　　　　　　　　　　　　　　　
 8　なすび　　15　　　　　　　　　　　　　　　
 9　トマト　　29　　　　　　　　　　　　　　　
10　いちご　　22　　　　　　　　　　　　　　　
 
B8
=SUM(FILTER(B$2:G$5,A$2:A$5=A8))
下方向・↓
古いバージョン
=SUMPRODUCT((A$2:A$5=A8)*TEXT(B$2:G$5,"0;-0;0;!0"))
下方向・↓
 
※遊びで
=MMULT(1*(TRANSPOSE(A2:A5)=A8:A10),MMULT(IFERROR(B2:G5*1,0),TRANSPOSE(1^COLUMN(B1:G1))))

こっちだった。古いバージョン
=SUMPRODUCT((A$2:A$5=A8)*(B$1:G$1="個数"),B$2:G$5)
下方向・↓

んなっと様
 
いつもありがとうございます！
できました！！
SUMPRODUCTは、条件がもう1つ必要だったんですね、
ありがとうございました(._.)//