スキルアップ・問題解決なら、モーグにおまかせ！

定型封筒の宛名の連続印刷のリストを下のように作りました。宛名のデータベースは１件ずつ横1行になっており、それをVLOOKUPで検索して封筒には差出先住所と宛先を横書き7行に印字されるようになっています。
宛名には住所1、住所2、住所3、入居建物名、会社名、担当者名、内容物などたくさんあるので、データベースの宛名の列数もその分だけあります。封筒の宛名人の行だけは様や御中などを選択して入れる必要があるため、特定の行で固定しています。そうすると、住所1と宛名人だけの最初の行と宛名人の行の２行で差し出す宛先もあれば、宛先7行とも目いっぱい使う宛先もあることから住所2から会社名の行の間に空行が出てバランスが悪くなることがあります。そのため、1件印刷に入るたびに空行を検索して非表示にしたあと印刷するようにしたいのです。
下のマクロのリストは、印刷開始番号から印刷終了番号までループで印刷を繰り返すものが第1のループで、その中に32列目の検索結果で空行を検索してその行を非表示にするループが第2のループです。
試してみたら、1件目の封筒だけは空行非表示になりますが、2件目以降は空行非表示のループを飛ばして第1ループの終了まで飛んでしまい、空行が入ったまま印刷されてしまいます。どこを直せばよいか分かりません。二重ループの書き方に詳しい方リストの拙いところを教えてください。よろしくお願いします。
 
Sub 長3封筒宛名選択印刷()
 
　Dim Pz, StNo,EndNo As Integer
  StNo = Range("N4")
  EndNo = Range("V4")
  Dim i As Long
  Dim LastRow As Long
 
  Sheets("長３封筒").Select
  ActiveSheet.PageSetup.PrintArea = "$B$3:$L$33"
          
  For Pz = StNo To EndNo        ’第1ループ開始
        Range("V1") = Pz
        If Pz = StNo Then
        LastRow Cells(Rows.Count,32).End(xlUp).Row    '基準列32列(AF)
    '行をループ　　最終から13行目まで
        For i =LastRow To 13 Step -1        ’第2ループ開始（空行非表示)
        If Cells(i,32) = "" Then
        Rows(i).Hidden = True '行を非表示
        End If
        Next i                     '第2ループ終了
　Application.Dialogs(xlDialogPrint).Show
　Else
　ActiveSheet.PrintOut
　End If
    Rows("13:19").Select
    Selection.RowHeight = 23.25
　Next Pz                              '第1ループ終了
 
    Rows("13:19").Select                '印刷後すべての行を表示する
    Selection.RowHeight = 23.25
  ActiveSheet.PageSetup.PrintArea = False
　Range("C12").Select
　End Sub

提示されたコードを内容は変えずに、インデントをつけてみました。
(手作業ではなく、実行したのはツールですが）
ご覧になって、ヒントになることがあれば幸いです。
 

Sub 長3封筒宛名選択印刷()
    Dim Pz, StNo, EndNo As Integer
    StNo = Range("N4")
    EndNo = Range("V4")
    
    Dim i       As Long
    Dim LastRow As Long
    Sheets("長３封筒").Select
    ActiveSheet.PageSetup.PrintArea = "$B$3:$L$33"

    For Pz = StNo To EndNo        '第1ループ開始
        Range("V1") = Pz
        If Pz = StNo Then
            LastRow Cells(Rows.Count, 32).End(xlUp).Row  '基準列32列(AF)
            '行をループ　　最終から13行目まで
            For i = LastRow To 13 Step -1       '第2ループ開始（空行非表示)
                If Cells(i, 32) = "" Then
                    Rows(i).Hidden = True    '行を非表示
                End If
            Next i                     '第2ループ終了
            Application.Dialogs(xlDialogPrint).Show
        Else
            ActiveSheet.PrintOut
        End If
        Rows("13:19").Select
        Selection.RowHeight = 23.25
    Next Pz                              '第1ループ終了

    Rows("13:19").Select                '印刷後すべての行を表示する
    Selection.RowHeight = 23.25
    ActiveSheet.PageSetup.PrintArea = False
    Range("C12").Select
End Sub

ありがとうございます。
ループを追加したり、元の行高に戻してループに返ったりしてコードを追加するのでインデントそろえはいい加減になってしまいます。申し訳ありません。

いえいえ申し訳ないことはありません。
ご自分に返ってきているだけの話なので、こちらは一向に構いません。
  
インデントをつけるとコードの論理構造が分かりやすくなるのでは？という話です。
インデントを付けたコードにご覧になって、何か気づいたことはありませんか？
ループの初回だけ実行したいことは何ですか? コードはそのようになっていますか？
  
# 回答を待っておられるようですけど、打ち返すべきボールはそちらにあると思っています。

シナモンジンジャー さんの引用:

試してみたら、1件目の封筒だけは空行非表示になりますが、2件目以降は空行非表示のループを飛ばして第1ループの終了まで飛んでしまい、

'    For Pz = StNo To EndNo        '第1ループ開始
    Pz = 18 '←Pzを直接指定してデバック
        Range("V1") = Pz
       '< Pzで指定した1件を印刷コードを作成する>
'　Next Pz                         '第1ループ終了

    For Pz = StNo To EndNo        '第1ループ開始
'    Pz = 18 '←Pzを直接指定してデバック
        Range("V1") = Pz
       '< Pzで指定した1件を印刷コードを作成する>
    Next Pz                       '第1ループ終了

なぜ、直接、値を当てはめた後わざわざデバッグするのでしょうか。
 
 

引用:
Pz = 18 '←Pzを直接指定してデバック
        Range("V1") = Pz
       '< Pzで指定した1件を印刷コードを作成する>

ちょっと教えてください。
 
＞32列目の検索結果で空行を検索してその行を非表示にするループが第2のループです。
 
その列の空白は、本当の空白ですか(所謂未入力セル？）
それとも数式で出した空白文字ですか？（通常は→ "" )
 
その判定に使われる範囲は「AF13:AF19」で確定的なんでしょうか？
また、AF13は含めても意味がない気がするんですが・・

封筒の各行にVLOOKUPで番号検索された値が代入されていますが、AF列(封筒印刷範囲のそと)には、その値（つまりデータベースで空白になっているセル値）は""を返すようにしてあります。その空白セルを検索してその行を非表示にしています。それで、それぞれの宛名データが代入されるたびにAF13からAF17までは""を返されたセルが変わってきます。

>AF13からAF17までは""を返されたセルが変わってきます。
そうですか・・、
13行目が非表示になることは現実的に無いと思ったのですが、
早とちりでしたか。
 
さて、 第2ループを開始する条件が If Pz = StNo となっていますが、
それだと、1回目だけ非表示処理をすると言う意味なので、
目的に合っていないと思います。
 
条件は、「AF13:AF19 に空白が有ったら」となるべきなので
 
>If Pz = StNo Then
 ↓
 If Application.CountIf(Range("AF13:AF19"), "") Then 'としたらどうですか？
 若しくは
 If Application.CountIf(Range("AF13:AF17"), "") Then
　　　　　　　　　　　　　　　　　　　↑
　　　　　　　　　　　　　　　　　　なのかなぁ・・
　　　　　　　　　　　　（ちょっとこっちでは何が正しいのか分からないです）
 
※あと、LastRowを取得する意味もちょっと分からないです。
　チェック範囲は　AF13:AF19(or AF13:AF17) だと思うので、
  その範囲に限定した方が簡明だと思います。
　また、LastRowは毎回同じハズなので、
  ループの中に入れるのは無駄ではないか、と言う気がします。
　まっ、以上の点は今回スルーしますけど。

Pz は　$V$1の宛先の印刷番号を代入する変数で　
i　は　$AF列の複数宛名行の有無を代入する変数です。
これを一緒にループすることはできないのですが。

初回と二回目以降で区別するのは、出力の仕方だけではないんですか？

       If Pz = StNo Then
            Application.Dialogs(xlDialogPrint).Show
       Else
            ActiveSheet.PrintOut
       End If

私のイメージしている二重ループは、第1のループで宛名一覧表（データベース）の中から、印刷開始番号をPzに代入して印刷開始番号１の宛名（宛名1〜会社名又は担当者名まで）を封筒の各行のVLOOKUPで表示させます。
その状態で第2のループに入り、封筒の各行のうち値が返された行には目印の「1」を、何も返さなかった行には「""」をAF列に反映させておいて、AF列の最下行(1048576行目)から上方へ13行目までを検索して「""」を返された行は非表示にしていき、完了したら第2のループは終了します。
そして、第1ル−プの作業であるプリントアウトをしたあと、Pzの次値を$V$1に代入して、印刷開始番号の次号の宛名（宛名1〜会社名又は担当者名まで）を封筒の各行のVLOOKUPで表示させておいて、同じようにループ2に進み、空行を検索して非表示にした後、プリントアウトに入るというイメージです。
1件ごとに宛名が2行だけだったりそれ以上〜7行だったりするのでプリントアウトが1件終わるたびに全行表示に戻す作業も入れてあります。
1件目の宛名印刷ではちゃんと空行を検索して非表示作業をしてプリントするのに、次の印刷番号を$V$1に代入したあとは第2ループを飛ばしてしまい、空行非表示の作業をせず第1ループの作業（次のプリントアウト）だけをするので、なぜそうなるのか分からないのです。
毎回の第1ループのなかで毎回第2ループの作業をさせて、第1ループに戻すというコード進行の書き方を具体的に教えてください。自己流でなんとかシンプルなマクロの書き方を覚えたので、今回の二重ループは難関です。よろしくお願いします。

引用:
1件目の宛名印刷ではちゃんと空行を検索して非表示作業をしてプリントするのに、次の印刷番号を$V$1に代入したあとは第2ループを飛ばしてしまい、空行非表示の作業をせず第1ループの作業（次のプリントアウト）だけをするので、なぜそうなるのか分からないのです。

        If Pz = StNo Then
            LastRow Cells(Rows.Count, 32).End(xlUp).Row  '基準列32列(AF)
            '行をループ　　最終から13行目まで
            For i = LastRow To 13 Step -1       '第2ループ開始（空行非表示)
                If Cells(i, 32) = "" Then
                    Rows(i).Hidden = True    '行を非表示
                End If
            Next i                     '第2ループ終了
            Application.Dialogs(xlDialogPrint).Show
        Else
            ActiveSheet.PrintOut   
        End If

Sub 長3封筒宛名選択印刷()
    Dim Pz As Long, StNo As Long, EndNo As Long '変数の型の宣言はひとつひとつに必要
    StNo = Range("N4")      '"長３封筒"と違うシートなら、シート名を特定する必要?
    EndNo = Range("V4")

    Dim i       As Long
    Dim LastRow As Long
    
    Sheets("長３封筒").Select
    ActiveSheet.PageSetup.PrintArea = "$B$3:$L$33"
    LastRow = Cells(Rows.Count, "AF").End(xlUp).Row     '基準列

    For Pz = StNo To EndNo
        Range("V1") = Pz                 '基準データセルの更新。
                                         'これによって他のセルが再計算される
        For i = LastRow To 13 Step -1    '空行非表示処理
            If Cells(i, "AF") = "" Then
                Rows(i).Hidden = True
            End If
        Next i
        '印刷処理
        If Pz = StNo Then
            Application.Dialogs(xlDialogPrint).Show
        Else
            ActiveSheet.PrintOut
        End If
        Rows("13:19").RowHeight = 23.25  '全行表示に
    Next Pz

    ActiveSheet.PageSetup.PrintArea = False
    Range("C12").Select
End Sub

シナモンジンジャー さんの引用:
2件目以降は空行非表示のループを飛ばして第1ループの終了まで飛んでしまい、空行が入ったまま印刷されてしまいます。どこを直せばよいか分かりません。二重ループの書き方に詳しい方リストの拙いところを教えてください。

シナモンジンジャー さんの引用:

1件目の宛名印刷ではちゃんと空行を検索して非表示作業をしてプリントするのに、次の印刷番号を$V$1に代入したあとは第2ループを飛ばしてしまい、空行非表示の作業をせず第1ループの作業（次のプリントアウト）だけをするので、なぜそうなるのか分からないのです。

シナモンジンジャー さんの引用:
なぜ、直接、値を当てはめた後わざわざデバッグするのでしょうか。

補足しますが、シナモンジンジャー さんは、ネストを理解・意識してますか。ネストを理解してないと、
・IF文でインデント下げをする理由。
・多重ループ
・インデントでネストを表現 する
を理解できません。
 
 
二重ループが分からないのではなく
　「入れ子」
を理解してないのでは。と推測しますが。
 
 

何回も丁寧なご説明ありがとうございます。教えていただいたコードを見てみると$V$1の値をpZに代入してすぐに空白処理に入り、そのあと連続印刷作業の第1ループに入っているように見えました。
書かれている通り

引用:
　初期設定
　第１ループ開始
　　判定
　　　第２ループ開始
　　　　行非表示
　　　第２ループ終了
　　行再表示
　第1ループ終了
　後処理

自分で考え書いたコードを動かしてみたけど、思い通りの結果が得られない。
これはよくある話です。
 
基本、問題が起きるのは、想定していたフロー とは違うフローでプログラムが進むから。
想定していたフローにならないのは、
　・条件分岐を入れる位置がそもそも違う
　・条件分岐の式が違う
のどちらかである事が多く、プログラムがどんなフローで進んでいるかを把握しなくては
どの部分に問題があるのかを把握できません。
 
その間違いを探し修正する必要があり、その修正作業をデバッグと言います。
 
質問者さんは、そのデバックの方法を知らないのではないですか？
 
デバックの為には、どの条件分岐でどんな判定がされるかを目に見える形にして
デバック者が コードフローを把握する必要があります。
 
その為にはいろんな方法があります。
・コードの中に MSGBOX を入れ 今どの部分のコードが進んでいるのかを目に見える様にする
・ブレークポイントを設置し、あるコード位置に来たらコードが止まる様にし 変数の内容等を確認する
・ステップ実行を行い、実際に どんな 順番でコードが進んでいるか 1行づつ追っていく
 
質問者さんは、それらを ひとつでもご存じですか？
それを自分でできないなら、コードを作るのは、とても難しくなります。
 
ExcelVBA入門 自宅でプログラミング
　デバッグの意味とデバッグ手法
https://www.239-programing.com/excel-vba/basic/basic020.html
 
を参考にし、デバックの方法を学び習得してください。
 
デバックを行う様になっていくと、
多層的な条件分岐についても見るはずです。
 
今のコードが実行されるには、どんな条件分岐を通ってきたのかを把握する必要があります。
 
例えば
 If 一番目の判定 Then
　　If 二番目の判定 Then
    Else
      If 三番目の判定 Then
      End If
　　End If
Else
　　〜〜
End If
 
こんな感じにインデントをつけておけば
 三番目の判定の段階では
　　一番目 の 判定 が True、二番目の判定 が Else の場合と 判りやすくありませんか？
それが、インデントがある事で分かり易くなります。
 
デバックを知らない人にしてみたら、インデントの必要性が判りませんよね。
どんな条件分岐を通って そこに至ったのかを考えた事無いですから。
自分でコードの動作を追うと、インデントがある事のメリット理解できる様になります。
 
まずは、デバックのしかたについて身につけましょう。

Suzuさまには、基本的なコード進行の方法を指摘していただきありがとうございます。私は、VBAの標準モジュールの画面を開いて、F8キークリックで1行ずつ確かめながらコード進行を見ているのですが、第1ループから第2ループに入って1通目を印刷したので、今度は次の宛名番号が代入されたところからF8キークリックで進行していくと第2ループを飛ばしてしまう状態はなぜそうなるかが分からなくてsimpleさまに教えていただいたところです。

シナモンジンジャー さんの引用:
F8キークリックで1行ずつ確かめながらコード進行を見ているのですが、第1ループから第2ループに入って1通目を印刷したので、今度は次の宛名番号が代入されたところからF8キークリックで進行していくと第2ループを飛ばしてしまう状態はなぜそうなるかが分からなくて・・・

 If　条件　Then
     処理1
 Else 
     処理2
 End If

オレンジと青の文字色で分けてくださって、私の書いたコードでは最初のIF〜End IFの条件文の中に違う作業のループが挟まっているのが分かりました。
お示しいただいたコードでは、Pzが代入されたら、まず空白行処理に入り、終了したら印刷に入り、もとの行高に戻したあと次のPzに進むというのが大変よくわかります。
  For〜 Next　の中に 第2ループの For〜 Nextの入れ方とIF〜End IFの分岐の書き方の順番が頭の中で整理てされよくわかりました。ありがとうございました。