Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 11 Home : Excel 2021)
シートに通しで連番
投稿日時: 25/02/02 10:47:43
投稿者: toma100

こんにちは、よろしくお願いいたします!
 
100くらいあるシートの表に一度に通しで連番つけることは可能でしょうか?
シート名には数値がない文字列です。
以下のようにあらかじめ作成した表があり、通しで一度に連番つけたいです。
 
シート名「田中」
番号 商品名・・
 
シート名「佐々木」
番号 商品名・・
 
と100くらいのシートがあり、
A列の番号に
 
シート名「田中」
番号 商品名・・
1
2
3
 
シート名「佐々木」
番号 商品名・・
4
5
 
とつけていきたいです。
それそれのシートはデータが追加されていきます。
シートをグループ化して一度に可能でしょうか?
よろしくお願いいたします。
 
 
 

投稿日時: 25/02/02 10:49:01
投稿者: toma100

追記です。
立場上,VBAが使えないので数式で可能にしたいのです。
よろしくお願いいたします!

回答
投稿日時: 25/02/02 13:09:20
投稿者: WinArrow

シート名は、"Sheet1","Sheet2"デフォルトを使用しています。
 
各シートのレイアウト
1行目は、項目名とします。番号列をAとします。
途中スペースセルがないこととします。
数式にはシート名が入ります。
 
例、Sheet2の場合
セルA2:=OFFSET(Sheet1!A1,COUNTA(Sheet1!A:A)-1,0)+1
セルA3:=A2+1
セルA4:=A3+1
 
シート1のセルA2以降には、数値のみ入力する

回答
投稿日時: 25/02/02 13:18:04
投稿者: んなっと

 どこかにシート名一覧を作成その範囲を選択
→数式
→名前の定義
 名前:mySh
→OK
→全シートを選択(別名グループ化した状態)
→A2を選択して次の数式を入れる
=SEQUENCE(COUNTA(B:B)-1,,IFERROR(MAX(INDIRECT(INDEX(mySh,TEXT(SHEET(A1)-1,"0;;;"))&"!A2#")),0)+1)
 
【追記】シート名一覧を作らない方法
 ...現在では推奨されない方法で、マクロ有効ブック(*.xlsm)で保存する必要がありますが
 数式
→名前の定義
→名前:mySh
 参照範囲:
=REPLACE(GET.WORKBOOK(1),1,FIND("]",GET.WORKBOOK(1)),)&T(NOW())
→OK

回答
投稿日時: 25/02/02 13:18:32
投稿者: WinArrow

数式で対応するには、シート名を変数化(例えば、「1つ前のシート」というような)できません。

投稿日時: 25/02/02 14:13:59
投稿者: toma100

WinArrow様、ありがとうございます!」
 
シート名を変数化、できないんですね、ありがとうございました(._.)
 
んなっと様、ありがとうございます!
できました!!!
すべてのシートに一気につけられて感激です☆彡
ありがとうございました(._.)