スキルアップ・問題解決なら、モーグにおまかせ！

フォームにIDを入力して実行ボタンをクリックすると，
該当する名前や住所等をフォームに表示させる様にマクロを作成し，問題なく動くのですが，
参照するファイルは必ず開く様にしないと無理なのでしょうか．
 
ちなみにこんな感じで作成しました
 
'入力したidをセット
id = TextBox1.Value
 
，参照ファイルとシートの指定
Set datafaile = Workbooks.Open("サーバー上のファイルの保存先")
Set wsData = dataBook.Sheets("ユーザー情報")
 
'該当するIDの行のデータを見つける
Set foundRow = wsData.Columns(1).Find(What:=sapid, LookIn:=xlValues, LookAt:=xlWhole)
 
'指定のボックスに表示
TextBox11.Value = wsData.Cells(foundRow.Row, 9).Value

引用:

参照するファイルは必ず開く様にしないと無理なのでしょうか．

どうもありがとうございます．
参照シートはリスト形式です
ADODBは知りませんでしたので，使い方を調べてみます．

Find を行っているのは、Loop を想定しているのでしょうか？
 
単一値 に対しての検索であり、同じ行の 9列目の値を取得したいのであれば
VLOOKUP では 不足なのでしょうか？
 
セル関数で、
=VLookUp検索値1,'C:\〜〜\[DATA.xlsx]Sheet1'!$A$1:$I$1000,9,0)
で、当該ファイルを開かなくとも取得できませんか？
 
 
それで満足するなら、
その数式を、VBA で、
セルの関数として 設定してあげれば良いでしょう。
 
Range("A1").FormulaLocal = "=VLookUp検索値1,'C:\〜〜\[DATA.xlsx]Sheet1'!$A$1:$I$1000,9,0)"
 
あとは、必要に応じて A1 の値を取得すれば良いです。
 
※ WorksheetFunction で、VLookUp を使用する場合には
　対象となるファイルが開いていないとエラーになりますので
　一度、セルの関数として設定する案としています。

春麗さん、↓で発言されるなら、こちらのスレッドを放置しないでもらえませんか？
https://www.moug.net/faq/viewtopic.php?t=82987
 
ちなみに、
VLookUp検索値1...
とカッコが抜けていますが、織り込んでいただいていますよね。
VLookUp(検索値1...

少し変則的ですが、こちらに
IFで書いた内容をVBAに
https://www.moug.net/faq/viewtopic.php?t=83062
のコメントを書きます。（新しいスレッドを建てるのもどうかと思いまして）
 
Excel365なら、B4セルに以下の式を入れますね。

=LET(
    n,COUNTIF(E4:F4,"あり"),
    IFS(AND(D4="A",n>0),"R1",
        AND(D4="A",n=0),"R2",
        AND(D4="B",n>0),"R2",
        AND(D4="B",n=0),"R3",
        D4="C","R3",
        TRUE,"")
)

Sub test()
    Dim n As Long
    Dim s As String
    
    n = Application.CountIf(Range("E4:F4"), "あり")
    Select Case Range("D4")
        Case "A": If n > 0 Then s = "R1" Else s = "R2"
        Case "B": If n > 0 Then s = "R2" Else s = "R3"
        Case "C": s = "R3"
        Case Else: s = ""
    End Select
    Range("B4") = s
End Sub 

simple さん も書かれていたので 当方も用意していた回答を。。
 
ワークシート関数を正として VBAに置き換えるなら
 
標準モジュール
--------------------------------------------------------------------------------
Function fnc_B(D As Range, E As Range, F As Range) As Variant
  If D = "A" Then
    If E <> "あり" And F <> "あり" Then
      fnc_B = "R1"
    End If
    If E = "あり" Or F = "あり" Then
      fnc_B = "R2"
    End If
  Else
    If D = "B" Then
      If E <> "あり" And F <> "あり" Then
        fnc_B = "R2"
      End If
      If E = "あり" Or F = "あり" Then
        fnc_B = "R3"
      End If
    Else
      If D = "C" Then
        fnc_B = "R3"
      End If
    End If
  End If
End Function
--------------------------------------------------------------------------------
 
B4 : =fnc_B(D4, E4, F4)
 
でしょうか｡
 
ユーザー定義関数にして、3つの引数を渡す様にしています。
 
 
ワークシート関数式 と 動作に関して違いがあります。
　ワークシート関数式：D4 に入力する値が、アルファベット 大文字小文字 に関わらず判定
　VBA　　　　　　　：D4 に入力する値が、アルファベット 大文字　　　のみ　　　　判定
 
大文字 小文字 でも 同じ判定にするなら、
　・小文字でも同じ判定結果となる条件式にする
　・モジュール先頭に、Option Compare Text を入れる
のどちらかで行います｡
 
 
 
If 〜 （Else 〜） End の 入れ子 構造が多く、条件判定の回数も多く 可読性が悪い ので
今回の様に､3つ のセルを参照し､それぞれのセルで入っている値が決まっているなら
Select Case を使う方が好みです｡
 
大文字小文字 に関わらず 同じ様に判定する も入れています。

Function fnc_B_rev(D As Range, E As Range, F As Range) As Variant
    fnc_B_rev = 0
    Select Case StrConv(D, vbUpperCase) & (E = "あり" Or F = "あり")
      Case "A" & False: fnc_B_rev = "R1"
      Case "A" & True:  fnc_B_rev = "R2"
      Case "B" & False: fnc_B_rev = "R2"
      Case "B" & True:  fnc_B_rev = "R3"
      Case "C" & False: fnc_B_rev = "R3"
      Case "C" & True:  fnc_B_rev = "R3"
      Case Else
    End Select
End Function