スキルアップ・問題解決なら、モーグにおまかせ！

ここ最近、質問立て続けで申し訳ございません。。。
 
VBAフォームモジュールの質問です。
 
  
 
【フォームの説明】
・OptionButton1→隣に　TextBox1　＆　ComboBox1
・OptionButton2→隣に　TextBox2
  
 
【プロパティ設定】
TextBox1　＆　TextBox2　＆　ComboBox1
Enabled = False
BackColor = &H80000000（灰色）
 
  
【やりたいこと】
OptionButton1をクリックしたら、TextBox1とComboBox1は編集可能にしバックカラーを白（&H80000005）にする。TextBox2は編集不可にしバックカラーを灰色にする。
OptionButton2をクリックしたら、TextBox2は編集可能にしバックカラーを白にする。TextBox1とComboBox1は編集不可にしバックカラーを灰色（&H80000000）にする。
  
 
【今まで私のコード】

Option Explicit
Private Sub OptionButton1_Click()
            ComboBox1.Enabled = True
            ComboBox1.BackColor = &H80000005
            TextBox1.Enabled = True
            TextBox1.BackColor = &H80000005
            TextBox2.Enabled = False
            TextBox2.BackColor = &H80000000
End Sub

Private Sub OptionButton2_Click()
            ComboBox1.Enabled = False
            ComboBox1.BackColor = &H80000000
            TextBox1.Enabled = False
            TextBox1.BackColor = &H80000000
            TextBox2.Enabled = True
            TextBox2.BackColor = &H80000005
End Sub

'funk(arg)の値がTrueであれば、argは、「Enabled = True（編集可）」「BackColor = &H80000005（白色）」になる。
'funk(arg)の値がFalseであれば、argは、「Enabled = False（編集不可）」「BackColor = &H80000000（灰色）」になる。


 Public Function funk(arg As String) As Boolean
        If funk(arg) = True Then
            arg.Enabled = True
            arg.BackColor = &H80000005
        Else
            arg.Enabled = False
            arg.BackColor = &H80000000
        End If
End Function

Private Sub OptionButton1_Click()
        funk(TextBox1) = True
        funk(ComboBox1) = True
        funk(TextBox2) = False
End Sub
 

Private Sub OptionButton2_Click()
        funk(TextBox1) = False
        funk(ComboBox1) = False
        funk(TextBox) = False
End Sub

'funk(arg)の値がTrueであれば、argは、「Enabled = True（編集可）」「BackColor = &H80000005（白色）」になる。
'funk(arg)の値がFalseであれば、argは、「Enabled = False（編集不可）」「BackColor = &H80000000（灰色）」になる。

Public Function funk(arg As String) As Boolean
            arg.Enabled = True
            arg.BackColor = &H80000005
End Function
 
Public Function funk2(arg As String) As Boolean
            arg.Enabled = False
            arg.BackColor = &H80000000
End Function

 
Private Sub OptionButton1_Click()
        funk(TextBox1) = True
        funk(ComboBox1) = True
        funk2(TextBox2) = False
End Sub
 
Private Sub OptionButton2_Click()
        funk(TextBox2) = True
        funk2(TextBox1) = False
        funk2(ComboBox1) = False
End Sub

コード簡素化の一例を挙げてみます。参考にしてください。
 

Private Sub OptionButton1_Click()
    setEnableTrue ComboBox1, TextBox1
    setEnableFalse TextBox2
End Sub

Private Sub OptionButton2_Click()
    setEnableTrue TextBox2
    setEnableFalse ComboBox1, TextBox1
End Sub

'ヘルパー用プロシージャ
Private Sub setEnableTrue(ParamArray objs() As Variant)
    Dim k&
    For k = LBound(objs) To UBound(objs)
        objs(k).Enabled = True
        objs(k).BackColor = &H80000005
    Next
End Sub
Private Sub setEnableFalse(ParamArray objs() As Variant)
    Dim k&
    For k = LBound(objs) To UBound(objs)
        objs(k).Enabled = False
        objs(k).BackColor = &H80000000
    Next
End Sub

 
↓のようなことをしたいのではないですか？
 

Option Explicit
'
'Public Function funk(arg As String) As Boolean
'        If funk(arg) = True Then
'            arg.Enabled = True
'            arg.BackColor = &H80000005
'        Else
'            arg.Enabled = False
'            arg.BackColor = &H80000000
'        End If
'End Function
　　↓
Private Sub funk(ByRef arg1 As MSForms.Control, ByVal arg2 As Boolean)
    With arg1
        If arg2 Then
            .Enabled = True
            .BackColor = &H80000005
        Else
            .Enabled = False
            .BackColor = &H80000000
        End If
    End With
End Sub

'Private Sub OptionButton1_Click()
'        funk(TextBox1) = True
'        funk(ComboBox1) = True
'        funk(TextBox2) = False
'End Sub
　　↓
Private Sub OptionButton1_Click()
        Call funk(arg1:=TextBox1, arg2:=True)
        Call funk(arg1:=ComboBox1, arg2:=True)
        Call funk(arg1:=TextBox2, arg2:=False)
End Sub

'Private Sub OptionButton2_Click()
'        funk(TextBox1) = False
'        funk(ComboBox1) = False
'        funk(TextBox) = False
'End Sub
　　↓
Private Sub OptionButton2_Click()
        Call funk(arg1:=TextBox1, arg2:=False)
        Call funk(arg1:=ComboBox1, arg2:=False)
        Call funk(arg1:=TextBox2, arg2:=True)
End Sub

複数ある「オプションボタン/テキストボックス/コンボボックスの組み合わせ」に対して
共通のイベント処理を実装したい、という意味でおっしゃっているのであれば、
とりあえずクラスモジュールの使用を検討されることをお奨めします。

＞結果：
＞コンパイルエラー：代入式の左辺の関数呼び出しは、バリアント型またはオブジェクト型の値を返さなければなりません。
 
＞ Public Function funk(arg As String) As Boolean
 
＞funk(TextBox1) = True
 
関数は、何かを与えると何かの答えを返すものです。
 
文法的には、
括弧の中に受け取るもの、括弧の外に返すものを書いてください。
 
受け取るものを文字列型にしているけど、与える方はオブジェクトになっているよというエラーです。
 

Option Explicit

'コントロールを「名前(文字列)]で受け取る
Public Function funk(ByVal arg As String, ByVal flg As Boolean) As Boolean
    With Controls(arg)
        If flg = True Then
            .Enabled = True
            .BackColor = &H80000005
        Else
            .Enabled = False
            .BackColor = &H80000000
        End If
    End With
End Function

'コントロールを「オブジェクト」で受け取る
Public Function funk2(ByRef arg As MSForms.Control, ByVal flg As Boolean) As Boolean
    If flg = True Then
        arg.Enabled = True
        arg.BackColor = &H80000005
    Else
        arg.Enabled = False
        arg.BackColor = &H80000000
    End If
End Function

Private Sub OptionButton1_Click()
    Stop
    funk TextBox1.Name, True
    funk ComboBox1.Name, True
    funk TextBox2.Name, False
End Sub

Private Sub OptionButton2_Click()
    funk2 TextBox1, False
    funk2 ComboBox1, False
    funk2 TextBox2, True
End Sub

 OptionButtonのChangeイベントを使うべきだと思いますよ
 

 Private Sub OptionButton1_Change()
   SetEnable Me.TextBox1, Me.OptionButton1.value
   SetEnable Me.ComboBox1, Me.OptionButton1.value
 End Sub

 Private Sub OptionButton2_Change()
   SetEnable Me.TextBox2, Me.OptionButton2.value
 End Sub

 Function SetEnable(ByRef c As MSForms.Control, value As Boolean)
   c.Enabled = value
   c.BackColor = IIf(value, &H80000005, &H80000000)
 End Function

>受け取るものを文字列型にしているけど、与える方はオブジェクトになっているよというエラーです。
 
あ、説明を間違ってます＾＾；無視してください。

 こんな書き方をしたいのかな？

 Private Sub OptionButton1_Change()
    SetEnable(Me.TextBox1) = Me.OptionButton1.Value
    SetEnable(Me.ComboBox1) = Me.OptionButton1.Value
 End Sub
 Private Sub OptionButton2_Change()
    SetEnable(Me.TextBox2) = Me.OptionButton2.Value
 End Sub
 Private Property Let SetEnable(ByRef c As MSForms.Control, newValue As Boolean)
    c.Enabled = newValue
    c.BackColor = IIf(newValue, &H80000005, &H80000000)
 End Property

Option Explicit

Private Sub OptionButton1_Click()
    SetEnabled 1
End Sub

Private Sub OptionButton2_Click()
    SetEnabled 2
End Sub

Private Sub SetEnabled(ByVal i As Long)
    Dim c As MSForms.Control
    Dim j As Long
    
    For Each c In Controls
        Select Case TypeName(c)
            Case "TextBox", "ComboBox"
                j = StrReverse(Val(StrReverse(c.Name)))
                c.Enabled = IIf(i = j, True, False)
                c.BackColor = IIf(i = j, &H80000005, &H80000000)
            Case Else
        End Select
    Next
End Sub

simple様
WinArrow様
sk様
mattuwan44様
gombohori様
 
ひぃーー、皆様ありがとうございます泣
一旦内容を確認させていただくのでしばしお返事にお時間をいただけますでしょうか・・。
 
当方のレベル
クラスモジュールまったく不明（ここ最近になって興味をしめしネットで検索するとまずファンクションプロシージャを使いこなせるようになるべきとかかれていたので、いまこちらにフォーカスを置いている感じです）
call を使ってSubプロシージャを呼び出すことはできるんですが、ファンクションってなんか全然Subプロシージャとレベルが段違いと悟り今まで回避していた感じです。。
（一応、VBAエキスパートは数年前に受かってはいるのですが・・・まぁ実際かかないとなかなか実務に生かせないですよね・・）
 
あとは、仕事は、全然7でSE系でもなんでもないです（質問のレベルから察して頂いているかと思いますが爆）

引用:
OptionButtonのChangeイベントを使うべきだと思いますよ

 >というわけで、TrueでもFalseでもイベントが発生するので、
 デザイン時のプロパティの設定次第です
 TextBox2のEnabledがTrueなら当然 OptionButton2のValueもTrueにしておくべきです
 TrueでもFalseでもイベントが発生するのが、いいところでしょう
 
 >If OptionButton1.Value = lrue Then
 >が必要です。
 不要でしょう
 
  

simple様
 
確認できました！
コードだけでみると、ParamArrayってなんだ？から入り、心折れけましたが、
調べてF8でみたらイメージわきました！（複数を引数にするって感じ？のやつなんですね）
 
 
ファンクションがなくても、サブプロシージャーに引数つければこんなことができるんですね。（自分で作るサブプロシージャーは毎度引数なしでした。）
 
これなら私でも時間をかければ頑張って今後も応用編ができるかも？と思いました。（いや多分相当頑張らないとだめですが）
 
 
そして、プロシージャーの命名が超わかりやすかったです。
「リーダブルコード」ですね！
書籍のおすすめ、めちゃくちゃありがたいです！
ネットでいまチラってみましたが、私もプロシージャや変数のネーミングに毎回悩んでは、利用するときに「なんだっけこのプロシージャ」ってなっていた気がします（汗）。
 
よんでみます。（そもそも私がもっている参考書って、KENスクールでつかっていたスクール専用教科書なので、もっとコード実務的な本を読むべきかもしれませんね‥なんかいい本あれば‥）
 
毎度心得的なものも教えていただきハッとさせられます、ありがとうございます＞＜。
 
 
【他の皆様、コメント返信もう少しお時間ください・・泣　※自分の知らない（多分聞いたことがあるけど、理解できてない）単語がありすぎて、愕然中ですが、調べまくってます】

VBAにはいろいろな機能がありますが、その機能を理解して適切な場所で適切な方法で使う必要があります。
 
プロシージャにはSubプロシージャとFunctionプロシージャがありますが、下記の違いがあります。
Subは特定の処理を実行する。
Functionは特定の処理を実行した後、結果を値として返す。
 
今回の質問の要件は、オプションボタンの値によって、テキストボックスとコンボボックスのEnabledとBackColorを変化させる、という処理です。
結果を値として返す必要がないのでFunctionである必要はありません。
 
複雑な処理で場合によっては失敗することがあり、処理が成功したか失敗したかによって以降の処理が変わるというような場合ではFunctionにしますが、今回はそのような必要もないでしょう。
 
----
オプションボタンですが、複数のオプションから一つを選択するという機能を持つものです。
 
質問のコードでは、オプションボタンのクリック時にすべてのテキストボックス、コンボボックスのプロパティを変更するというコードを書いてますが、この書き方だとオプションや関連付けられるコントロールが多くなると、それにつれてコードが複雑化します。
 
一つのオプションをクリックすると選択されてChangeイベントが発生し、選択が解除されたオプションでもChangeイベントが発生します。
Changeイベントを利用すると関連付けられたコントロールのプロパティを変更するだけで済みます。
 
---
オプションボタンに複数のコントロールを関連付ける場合、可変数の引数をとることができるParamArrayステートメントをうまく使うとコードを簡素化できます。
 
すでにいろいろなコード例が出ていておなかいっぱいだと思いますが、一例を置いておきます。
 

Private Sub OptionButton1_Change()
    SetEnabled Me.OptionButton1, Me.TextBox1, Me.ComboBox1
End Sub

Private Sub OptionButton2_Change()
    SetEnabled Me.OptionButton2, Me.TextBox2
End Sub

Private Sub SetEnabled(OptBtn As MSForms.OptionButton, ParamArray LinkCtls() As Variant)
    Dim ctl As Variant
    For Each ctl In LinkCtls
        ctl.Enabled = OptBtn.Value
        ctl.BackColor = IIf(OptBtn.Value, &H80000005, &H80000000)
    Next
End 

WinArrow様
ありがとうございます泣
確認しました！。
文法的にいうと、
 
arg1のコントロールにおいて…
arg2がTrueであれば　（If arg2 Thenって、If arg2＝True Then と同じですよね　うんきっとそうだ‥）
arg1.Enabled = True
arg1.BackColor = &H80000005
 
arg2がTrue以外であれば（つまりFalse）
arg２.Enabled = True
arg２.BackColor = &H80000005
ってことですね・・！
 
（simple様がいっていた、# （さらに一つに纏めて、rue,Falseを引数にする手もあるかもしれません。ってやつがこやつですね！）
  
（ByRef arg1 As MSForms.Control, ByVal arg2 As Boolean）
ByRefとか ByVal（参照渡し、値渡し？）の理解は時間をかけて解読します。
 
AS　 MSForms.Control　がよくわからなくて（よく見てみると、自動作成のBeforeUpdateイベントプロシージャにも似たようなものありますね）まずはこれを勉強しないと今後も壁にぶちあたりそうなので精進します。
 
（ネットでしらべるとクラスモジュール前提のものばかりで、どこの理解から進めればいいか迷走しておりますがなんとかやってみます　T＿T）
 
  
 
sk様
ありがとうございます泣
クラスモジュールは全く知識ないのですが、色々調べているうちに、噂ではだいぶ便利な機能な気がしてなりませぬ・・。
クラスモジュールぜひ理解を深めていきたいと思います（引数付きのプロシージャー作成に慣れてからの方がいいのかなと自分で思ってます）
 
  
 
mattuwan44様
前回に引き続き、ありがとうございます泣泣
なんとなく、上から皆様のコメント見ているうちにAs MSForms.Controlの意味がわかりそうです（←理屈はわからないけど感覚的に！
 
Public Function funk(ByVal arg As String, ByVal flg As Boolean) As Boolean
 
の最後のAs Booleanがやはり何を返しているのかがわからず、まさかと思い、下記Subに改造して下記でもやってみたら同じく起動しました！
 
24/10/22 13:52:26のコメントも確認しました。
本件の例はやはり、ファンクションプロシージャーには向かなさそうな感じは私も皆様のコメントをみているうちに察しました爆。
 
でも文法的を入れていただけることで理解力増しました！ありがとうございます！
'コントロールを「名前(文字列)]で受け取る
 

Public Sub funk(ByVal arg As String, ByVal flg As Boolean)
    With Controls(arg)
        If flg = True Then
            .Enabled = True
            .BackColor = &H80000005
        Else
            .Enabled = False
            .BackColor = &H80000000
        End If
    End With
End Sub
 
'コントロールを「オブジェクト」で受け取る
Public Sub funk2(ByRef arg As MSForms.Control, ByVal flg As Boolean)
    If flg = True Then
        arg.Enabled = True
        arg.BackColor = &H80000005
    Else
        arg.Enabled = False
        arg.BackColor = &H80000000
    End If
End Sub

 Private Sub OptionButton1_Click()
'    Stop
    funk TextBox1.Name, True
    funk ComboBox1.Name, True
    funk TextBox2.Name, False
End Sub
 
Private Sub OptionButton2_Click()
    funk2 TextBox1, False
    funk2 ComboBox1, False
    funk2 TextBox2, True
End Sub

質問者さんへ
私のは前座ですので余り参考になりません。
gombohoriさんはじめchangeイベントプロシージャを使ったものがよいと思いました。
また、hatenaさんの投稿はよくまとまっていますし、大いに参考にしていただきたいです。

けけちゃま さんの引用:
当方のレベル
クラスモジュールまったく不明

けけちゃま さんの引用:
（ネットでしらべるとクラスモジュール前提のものばかりで、どこの理解から進めればいいか迷走しておりますがなんとかやってみます　T＿T）

けけちゃま さんの引用:
Public Function funk(ByVal arg As String, ByVal flg As Boolean) As Boolean
 
の最後のAs Booleanがやはり何を返しているのかがわからず、まさかと思い、下記Subに改造して下記でもやってみたら同じく起動しました！

けけちゃま さんの引用:
AS　 MSForms.Control　がよくわからなくて

けけちゃま さんの引用:

ByRefとか ByVal（参照渡し、値渡し？）の理解は時間をかけて解読します。

引用:

（If arg2 Thenって、If arg2＝True Then と同じですよね　うんきっとそうだ‥）

Sub test()
Dim arg2 As Boolean

    arg2 = True
    
    If arg2 Then
        Debug.Print True
    End If
End Sub

>なんとなく、上から皆様のコメント見ているうちにAs MSForms.Controlの意味がわかりそうです
 
Microsoft Forms オブジェクト の中の様々なコントロー群
みたいなイメージです。
https://learn.microsoft.com/ja-jp/office/vba/language/reference/user-interface-help/objects-microsoft-forms
 
>For Each c In Controls
>ってフォームにあるすべてコントロールの数分繰り返すってことだと、コントロールが多くなると負担かかるも>のですかね。
 
数10個ぐらいではそんなに負荷はかからないんじゃないですかねぇ。。。
やってみて重いなら別案考えればいいかなぁ。。。
とりあえず、クリックイベントにこだわったら、
対象のものを探し回る必要があるかなぁとは思います。
(数が限られて、探さなくてもわかるなら直にコードに書きこんでも良いでしょう。）
 
＞参考書みてもファンクションプロシージャーじゃないとできない！っていうコードがよくわからなった
 
「ファンクションプロシージャーじゃないと」と考えずに、
「こんな関数があると便利だな」とか、
「本筋の話からそれるので、他のプロシージャに追い出したいな」
と思ったときにFunctionプロシージャを使うといいかと思います。
 
例えば、
hatenaさんのコードが、一番洗練されているかと思いますが、
 

 Function SetEnable(ByRef c As MSForms.Control, value As Boolean)
   c.Enabled = value
   c.BackColor = IIf(value, &H80000005, &H80000000)
 End Function

Function SetEnable(ByRef c As MSForms.Control, value As Boolean)
   c.Enabled = value
   c.BackColor = EnabledColor（value)
End

function EnabledColor(byref flg as boolean)as long
    enavledcolor = IIf(flg, &H80000005, &H80000000)
end function

gombohori様
WinArrow様
hatena様
  
 
Changeイベントようやく理解できました！
OptionButton1の値＝Trueの時は、
TextBox1の値＝True
ComboBox1の値＝True
の規則を利用するってことですね！（考え方あってますかね・・）
なんでそのような発想が・・・これは経験の差なのか、地頭の差なのか・・それともこれは王道コードでどこかの参考書に載っているものなのか…
いずれにしてもすごいと思いました。
 
gombohori様のPropertyプロシージャについては、これも全く無知なので、また一つ課題にさせてください、ありがとうございます・・！
（課題だらけ・・T＿T）
  
hatena様
すごく分かりやすい説明を頂きありがとうございます。
そして、ParamArrayについては最近ようやく理解したので、すごく洗練されたコードになり感動しました。（そしてそれがようやく読めるようになった自分に感動T＿T）
 
このコードを使ってみたいと思います。（ほかの皆様からも頂いたコードとても勉強になりました、ありがとうございます・・！）
  
 
WinArrow様
確認方法ご教示ありがとうございます。
まだ完全に理解できていないですが、多分Boolean型をちゃんと理解する必要があると思いましたのでこちら持ち帰ります泣！
  
mattuwan44様
enavledcolorの値をSetEnableに返す…まだ解読ができておりませんが、
きっとファンクションプロシージャーを勉強するにあたりきっと読めるようになると思うので参考にいたします、ありがとうございます！
というもの、一昨日からまた別件のバグ（OneドライブにいれたThisWorkbookのパスがおかしい）が生じて調べまくったら、
https://it-yobi.com/excel-b-noex24/
のサイトにたどり着き、なんとなくファンクションプロシージャーの値を返す意味がわかりかけました。
ファンクションプロシージャで得た値つかって、別の値をだすときに使うんだなと。（語彙力・・すみません）
  
MMYS様
ありがとうございます(´;ω;｀)
周りから「コードかけるんだすごね」と言われちょっとうれしくなったものの、
ここでの皆様のレベルに圧倒され、自分の非力さに穴があったら入りたいレベルでした…苦笑。
 
ブール型はなんとなくTrueとFalseなのはわかるんですが、
バリアント型がよくわからなくて（それ以外はバリアントって思っておけばいいのかなくらい）、
なんなら全部バリアント型のほうがいいのでは？と思うのですが、無駄に要領を使いすぎる感じなのかなと思ってます。
これは基礎知識になると思うので自分で調べてみます！
そして、「参照渡し・値渡し」の違いとデメリット（値渡しはコピー分速度が落ちる、なるほど！！）もありがとうございます。
すごくわかりやすかったです！。
 
 

皆様、この度は私の質問に対して色々ご意見をいただきありがとうございます。
精進いたします。
 
私にとって皆様は、プログラマーレベルとかってに思っているのですが、
皆様がここまでの知識になるまでに、ご愛用された参考書などがあれば教えていただきますでしょうか・・・＞＜。
（あまりに上級レベルはさすがにまだ敬遠したいと思っておりますが

　＞ファンクションプロシージャで得た値つかって、別の値をだすときに使うんだなと。
 
ちょっと違うかもです。
ブラックボックスという言葉をご存じないでしょうか？
その仕組みを自分で作るのが、functionプロシージャです。
 
自分で作って自分で使うのでわかり難いかも知れませんが。。。。
TrueかFalseかが分かっているときに、
Trueの色の値が欲しいときは、ブラックボックスにTrueを入れれば、期待した答えが返ってくる
反対も同様です。
それ以外を考えなくてもいいようにしたらどうかなという例でした。
例が無理やりなのでわかりずらいですよね＾＾；

本はもう卒業でいいのではないでしょうか？
ExcelVBAの情報は大体ネットで賄えるかと。
よく見るのはこの辺。。。
 
オフィス田中
http://officetanaka.net/index.stm
 
インストラクターのネタ帳
https://xn--relief-2o4e6c3dvc7eqthevf.jp/
 
Excelの神髄
https://excel-ubara.com/
 
Excel大事典
http://www4.plala.or.jp/gen2/excel/
 
Excelでお仕事！
https://www.asahi-net.or.jp/~ef2o-inue/top01.html
 
Addin Box
https://addinbox.sakura.ne.jp/
 
Functionプロシージャとかの話なら、
Excel大事典の「構造化プログラミングに挑戦」の項を読むといいかも知れません。

けけちゃま さんの引用:

皆様がここまでの知識になるまでに、ご愛用された参考書などがあれば教えていただきますでしょうか・・・＞＜。

mattuwan44様
MMYS様
 
ありがとうございます！
やはりまだまだ基礎がなっていないですよね・・（自分がどのレベルかもよくわからず）
今回、教えていただいた情報をもとにさらなる勉強を進めていきたいと思います！！
 
皆様
これにて解決済みにさせてはいただきます。
本当にありがとうございます！！