スキルアップ・問題解決なら、モーグにおまかせ！

'''book2 Thisworkbook モジュール
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Dim sh As Worksheet
For Each sh In Me.Worksheets
    sh.PrintPreview
Next
Me.Saved = True
MsgBox "ByeBye"
End Sub
 
'''book1 標準モジュール
Sub test()
Dim wb As Workbook
Set wb = Workbooks.Open(Filename:=ThisWorkbook.Path & "\Book2.xlsm")
wb.Close
Set wb = Nothing
End Sub
 
book2 を手動で開き、閉じると正しくプリントプレヴューし、メッセージ表示後閉じられますが、
book1 のマクロ test より実行するとプリントプレヴューされず、メッセージのみで閉じられてしまいます。
（とりあえず、テストでプレヴューにしています）
book1 のマクロからでもbook2終了時プリント（プレヴュー）させたいのですが、、、、
ご教授くださいませ。。

Excel365でも再現しますね。原因は不明です。
(1)表示されていないのか、
(2)表示されているが、ユーザーアクションを待たせることがスキップされているのか
画面がちらちらしないので、たぶん(1)のような気はしますけれども。
 
感想をメモします。（原因解明には貢献しませんけれども）
・BeforeCloseイベントプロシージャで印刷プレビューさせるという仕組みが、ちょっと悪手なのかもしれません。
 
・特に他のブックから開いて、マクロでなんらかの処理をさせる場合は、
プレビューするプロシージャーを標準モジュールに独立させておいて、
その処理の最後で明示的に、Application.Runでそのプレビュープロシージャを実行する、
というのが安全確実でしょう。
 
・加えて、closeのつどプレビューするのも、うざくなる時もあるのではないかと思います。
単に閲覧しただけのときもあるので。
必要な時にプレビューのプロシージャを意図的に実行する、という作りのほうが良いと思います。

この事象については、こちらでも再現しました。
Windows10　＆ Excel2019
ステップ実行の結果、
PrintPreviewコードが実行されてはいるが、画面表示されないという不思議n現象ですね？
原因は、よくわかりません
  
回答になっていなくてすみません。
 

BOOK1ががテストということなのですが、
 
代案を紹介します。
 
BeforeCloseプロシジャのコードを標準モジュールに移動します。
（BeforeCloseは削除、標準モジュール側のプロシジャ名を理に「PRINTSUB」とします）
 
Book1側に
 RUN wb.Name & "!PRINTSUB"
を、
wb,Closeの前に記述
 

引用:
Workbook_BeforeCloseにて印刷を実行したい

引用:
For Each sh In Me.Worksheets
    sh.PrintPreview
Next

引用:
book1 のマクロ test より実行するとプリントプレヴューされず、
メッセージのみで閉じられてしまいます。
（とりあえず、テストでプレヴューにしています）

book2のWorkbook_BeforeCloseを正常に動作させたいということであれば、book2のThisworkbookモジュールに以下のマクロ CloseEvent を追加します。
そのマクロをbook1のマクロ test より起動し、マクロ testでのbook2を閉じる際のイベントの発生は無効にしてみてはどうでしょうか？
 
'book2 Thisworkbook モジュール

Public Sub CloseEvent() '追加

    Call Workbook_BeforeClose(True)

End Sub

Sub test() '修正版

Dim wb As Workbook

    Set wb = Workbooks.Open(FileName:=ThisWorkbook.Path & "\Book2.xlsm")
    
    Application.Run wb.Name & "!Thisworkbook.CloseEvent" '追加したCloseEventを起動
    
    Application.EnableEvents = False　'イベントの発生を無効化
    
    wb.Close
    
    Application.EnableEvents = True  'イベントの発生を有効化
    
    Set wb = Nothing

End Sub

皆様、検証、助言、ありがとうございます。
非常に勉強になります。感謝です。
 
この度、提示させて頂いたコードは検証の為、省略したもので
何かと不審かとは思われますが、お付き合いいただきありがとうございました。
 
皆様の助言をもとに以下の通り Application.Run にて実行する形に落ち着きました。
ひとまず解決とさせて頂きます。
 
'''book1 標準モジュール
Sub test_2()
Dim wb As Workbook
 
Set wb = Workbooks.Open(Filename:=ThisWorkbook.Path & "\Book2.xlsm")
Application.Run wb.Name & "!Thisworkbook.CloseAfterPrg"
Set wb = Nothing
 
End Sub
 
 
'''book2 Thisworkbook モジュール
Sub CloseAfterPrg()
Dim sh As Worksheet
For Each sh In Me.Worksheets
    sh.PrintPreview
Next
MsgBox "ByeBye"
Me.Close SaveChanges:=False
End Sub