スキルアップ・問題解決なら、モーグにおまかせ！

600人ほどのデータがあり、Template用のシート(20人／頁）に転記して、
 
For n = 1 to 終頁
  （1）順次 20人ごとにデータ転記の作業
　　　 UserForm2.show
　（2）上の作業が終わった時点でページごとに「印刷して次頁、見るだけで次頁、中止」を
　　　 UserForm1から三択用UserForm2を呼び出して作業を1つ選択
　　　 Unload UserForm2
　 (3) (2)の３択を実行して(1)に戻る
Next
　　　のような感じの作業をしています。
 
　(2) ではMsgBoxではvbYesNoCancelの３択の用語が自由にならないようなので、使っていません。
　三択用UserForm2 を使わないでUserForm1の上に「印刷して次頁、見るだけで次頁、中止」の
　ボタンを配置して、作業(1)完了後に、(2)３択用ボタンで選択後、(3)三択の作業に移り
　また次の作業(1)に順次進むようにしてみたいのですが何か良い方法があるでしようか？
 
　　三択用UserForm2を使用すると画面があまり美しくありません。
 
　よろしくお願い致します
　
 
 
 

Userform1の中に三択用ボタンを配置するのでは、ダメなんですか？
三択用ボタンは、条件で非表示／表示を切り替えればよいでしょう
三択用ボタンを「フレーム」コントロール内に配置して
「フレーム」コントロールを非表示／表示する方法を提案します。
 
 
>画面があまり美しくありません
は、個人差があるので、アドバイスできません。

 WinArrow さんいつもありがとうございます。
 
作業(1)終了後、MsgBox（vbYesNoCancel）や　UserForm2.Show なら一度作業を止め
３択後作業を分岐して、また(1)に戻すことはできるのですが、
UserForm1に３択用のOptionBoxを配置しても、そこで一旦作業を止める方法が
思いつかないのです。

>（1）順次 20人ごとにデータ転記の作業
この作業は、Userfom1の中で実行しているですよね？
  
処理を止めたいのでしたら、
フレームを表示し、MSGBOXを使って（三択ボタン操作のアナウンスだけ）
止めれば、よいのでは？

For ... Nextループでは無理っぽいので、
転記処理をに別ルーチンして呼び出す方法はどうでしょう。
 
 
ユーザーフォーム上に[印刷作業開始]コマンドボタンがあるとします。
 
フレーム上(Frame1)に下記の３つのコマンドボタンを配置します。
[印刷して次頁] [見るだけで次頁] [中止]
 
ユーザーフォームに下記のコードを記述します。
 

Option Explicit
Private 処理頁 As Long
Private 終頁 As Long

Private Sub 転記作業()
    If 処理頁 > 終頁 Then
        MsgBox "最終頁まで作業完了しました。"
        Exit Sub
    End If

    MsgBox 処理頁 & "頁の転記作業実行"
    '実際の転記処理を記述
    
    Me.Frame1.Visible = True
End Sub

Private Sub 印刷作業開始_Click()
    処理頁 = 1
    終頁 = 20
    Call 転記作業
End Sub

Private Sub 印刷して次頁_Click()
    Me.Frame1.Visible = False
    
    MsgBox 処理頁 & "頁の印刷実行"
    '実際の印刷処理を記述
    
    処理頁 = 処理頁 + 1
    Call 転記作業
End Sub

Private Sub 見るだけで次頁_Click()
    Me.Frame1.Visible = False
    処理頁 = 処理頁 + 1
    Call 転記作業
End Sub

Private Sub 中止_Click()
    Me.Frame1.Visible = False
    MsgBox "作業を中止します。"
End Sub

hatena　さん　懇切丁寧なコードありがとうございます。
もう少し色々調べてみると、Do Until　と DoEvents を
利用すればMsgbox や UserForm2 を使わなくても、一旦作業を
中止して、３択に分岐してまた元に戻ることができました。
 
大雑把には次のようなコードです。
Private Sub 作成開始()
   Dim choice As Integer,n As Integer
  
   For n = 1 To 終頁
        ' ここで転機作業(コードは省略)
        Do Until choice <> 0
            DoEvents
        Loop
         
        Select Case choice
            Case 1 ' ComandButton1
                作業1 を実行
            Case 2 ' ComandButton2
                作業2 を実行
            Case 3 ' ComandButton2
                作業3 を実行
        End Select
 
   　　　If n > 終頁 Then
 　　 MsgBox "最終頁まで作業完了しました。"
    　　 Exit Sub
    　　End If
        choice = 0　' ユーザーの選択をリセットする
    Next n
End Sub
 
 
Private Sub CommandButton1_Click()
    choice = 1
End Sub
 
Private Sub CommandButton2_Click()
    choice = 2
End Sub
 
Private Sub CommandButton3_Click()
    choice = 3
End Sub
 
２日ほどしたら閉めさせていただきます。

taichi さんの引用:

もう少し色々調べてみると、Do Until　と DoEvents を
利用すればMsgbox や UserForm2 を使わなくても、一旦作業を
中止して、３択に分岐してまた元に戻ることができました。

Do ... Loop と DoEventsの待機でCPUの使用率を下げる方法はありますが、パフォーマンスは落ちます。
 
Office TANAKA - Excel VBA Tips[CPUの使用率を抑える方法]
http://officetanaka.net/excel/vba/tips/tips116.htm
 
下記の方法だと改善はされますが、やはりパフォーマンスは落ちます。
 
Access Tips #114 DoEventsをパフォーマンスを下げずに使う方法 | T'sWare
https://tsware.jp/tips/tips_114.htm
 
私の回答の方法だとパフォーマンスが落ちることはありません。

WinArrow　さん　hatena　さん　ありがとうございました。
これで解決とさせていただきます。