スキルアップ・問題解決なら、モーグにおまかせ！

お世話になります。
 
PDF出力をしたいのですが、わからずに困っているので教えてください。
 
 
現在、レポートで請求書をプリンターから印刷しておりますが、幾つかのお取引先様からPDFにしてメールで送るように変更するように言われました。
 
PDF化したいお取引先様だけ抽出することができたので、プリンターを「　Microsoft Print PDF 」に切り替えてPDFにしたところ、複数の会社の請求書が1つのファイルになってしまいました。
 
手作業で、お取引先様毎にページ指定をすればお取引先様ごとのファイルになるのですが、自動でお取引先様毎にファイルを別けるか、1ページずつPDFファイルにする方法はないでしょうか？
 
ネットで調べてみてもわからず、もし良い方法をご存知の方がおられましたら手順などご指導ください。
 
10月からのインボイス制度に間に合わせなくてはいけなく、困ってます。
 
よろしくお願い申し上げます。

引用:
現在、レポートで請求書をプリンターから印刷しておりますが、
幾つかのお取引先様からPDFにしてメールで送るように変更する
ように言われました。

引用:
手作業で、お取引先様毎にページ指定をすればお取引先様ごとの
ファイルになるのですが、自動でお取引先様毎にファイルを別けるか、
1ページずつPDFファイルにする方法はないでしょうか？

sk様
 
ご指導ありがとうございます。
 
ネットで調べてこちらのページを拝見させていただいたのですが、まったくわからずにおります。
 
https://tasukete-access.com/2023/01/18/vba_pdf_output/
 
https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q11280389871?__ysp=44Ki44Kv44K744K5ICBWQkEgIFBERg%3D%3D
 
https://oshiete.goo.ne.jp/qa/6681709.html
 
真似てマクロを試してみたのですが、エラーばかりで動作しなくていろいろ試してるのですが、そもそもVBAの知識がないのでわからずにおります。
 
もし、ご参考になるページなどご存知でしたら、すみませんがお教えください。
 
よろしくお願い申し上げます。

ではとりあえず、以下の情報を明記して下さい。
 
・請求書として使用されるレポートの名前。
 
・そのレポートの[レコードソース]プロパティの設定値。
 
・レポートのレコードソースがテーブルである場合は、
　そのテーブルの定義内容（各フィールドの名前、データ型、
　主キーに関する情報）。
 
・レポートのレコードソースがクエリである場合は、
　そのクエリの SQL ビューの内容。

引用:
手作業で、お取引先様毎にページ指定をすればお取引先様ごとのファイルになるのですが、自動でお取引先様毎にファイルを別けるか、1ページずつPDFファイルにする方法はないでしょうか？

sk様
  
お世話になります。
ご親切に、ありがとうございます。
 
 

引用:
・請求書として使用されるレポートの名前。

引用:
・そのレポートの[レコードソース]プロパティの設定値。

引用:
・レポートのレコードソースがクエリである場合は

引用:
フリーで、分割ツールはありますから

引用:
SELECT tokuisaki.[c-code],
       tokuisaki.tokuisaki,
       tokuisaki.shime,
       tokuisaki.post,
       tokuisaki.address,
       tokuisaki.tel,
       tokuisaki.fax,

引用:
c-codeで親子関係をしてます。

引用:
レポートの名前は、請求書_PDF発行　です。

引用:
WHERE (((Format([hiduke],"yy/mm"))=[Forms]![start]![tx1]))

sk様
  
ご指導ありがとうございます。
説明不足ですみません。
 
難しいことをお願いして、本当にすみません。
申し訳ないです。
 
 

引用:
フィールドのデータ型は何でしょうか。

引用:
フォーム[start]上のコマンドボタンの[クリック時]イベントで実行されているのでしょうか。

引用:
テキストボックスに今日の年と月を入力して、
フォーム上のボタンをクリックすると動くようになってます。

Private Sub cmdOutputPdfEachCustomer_Click()

    Const OutputReportName As String = "請求書_PDF発行"

    If Not Nz(Me![tx1].Value, "") Like "##/##" Then
        MsgBox "抽出対象となる売上年月を yy/mm 形式で入力して下さい。", _
               vbExclamation, _
               "入力エラー"
        Me![tx1].SetFocus
        Exit Sub
    End If

    Dim db As DAO.Database
    Dim qdf As DAO.QueryDef
    Dim rs As DAO.Recordset
    
    Set db = CurrentDb
    
    Set qdf = db.CreateQueryDef("")
    With qdf
        .SQL = "SELECT [c-code], [tokuisaki]" & _
               " FROM [請求書発行_PDF]" & _
               " GROUP BY [c-code], [tokuisaki]" & _
               " ORDER BY [c-code]"
        .Parameters("[Forms]![start]![tx1]").Value = Me![tx1].Value
        Set rs = .OpenRecordset(dbOpenSnapshot)
    End With
    
    If rs.EOF Then
        MsgBox "指定された年月において、出力対象となるデータはありません。", _
               vbInformation, _
               "データなし"
        Set rs = Nothing
        Set qdf = Nothing
        Set db = Nothing
        Exit Sub
    End If
    
    Dim strOutputFolderPath As String
    
    strOutputFolderPath = CurrentProject.Path & "\請求書PDF"
    
    If Dir(strOutputFolderPath, vbDirectory) = "" Then
        MkDir strOutputFolderPath
    End If
    
    strOutputFolderPath = strOutputFolderPath & "\" & Format(Now(), "yyyymmdd_hhnnss")
    
    If Dir(strOutputFolderPath, vbDirectory) = "" Then
        MkDir strOutputFolderPath
    End If
    
    Dim strOutputFilePath As String
    
    Do Until rs.EOF
        DoCmd.OpenReport OutputReportName, acViewPreview, , "[c-code]=" & rs![c-code].Value, acHidden
        strOutputFilePath = strOutputFolderPath & "\" & _
                            Replace(Me![tx1].Value, "/", "") & "_" & rs![c-code].Value & "_" & Nz(rs![tokuisaki].Value, "（名称不明）") & ".pdf"
        DoCmd.OutputTo acOutputReport, OutputReportName, acFormatPDF, strOutputFilePath
        Debug.Print strOutputFilePath & " を出力しました。"
        DoCmd.Close acReport, OutputReportName, acSaveNo
        rs.MoveNext
    Loop

    Set rs = Nothing
    Set qdf = Nothing
    Set db = Nothing

    Shell "explorer.exe """ & strOutputFolderPath & """", vbMaximizedFocus

    MsgBox "フォルダ'" & strOutputFolderPath & "'にPDFファイルを出力しました。", _
           vbInformation, _
           "実行完了"

End Sub

sk様
 
お世話になります。
ご親切に、ありがとうございます。
 
たいへんな、ご面倒とお手数をおかけして申し訳ございません。
こんなに、親切に助けていただいてすみません。
 
 
いただいた手順の通りに試しましたら、思うように動作しました。
ありがとうございます。
 
なんか、とても難しいコードで私にはとても作れないし理解もできていないのですが、動作するのを拝見して驚きと感動です。
 
なんと御礼を言ったら良いのか、言葉もわからずお恥ずかしいのですが、とっても嬉しくて本当にありがとうございます。
 
めちゃめちゃ嬉しいばかりです。
 
申し訳ないばかりで、ちゃんとしたお礼の言葉が言えずにすみませんが、本当にありがとうございます。
たいへん助かりました。
 
また困った時は、助けてください。
 
本当に本当にありがとうございます。
 
嬉しい限りです。
 
ありがとうございます。
 
よろしくお願い申し上げます｡