スキルアップ・問題解決なら、モーグにおまかせ！

下記のような「元の表」があったとします。
 
Ａ列とB列の両方に顧客番号があるものを除いた表を作成したいです。
その結果として「重複しない顧客番号」表になります。
かつ、顧客番号は若番順に並べます。
 
元の表    
A    　　　B
顧客番号　　顧客番号
370    　　650
250    　　490
146　　　　　47
47    　　250
250    　　146
650　 　　　160
360    　　450
 
 
重複しない顧客番号    
　A    　　B
顧客番号　顧客番号
    　160
360    
370    
    　450
    　490
 
 
このような事をするには、どうしたら良いでしょうか？
事務処理の消込作業と考えて頂いて結構かと思います。

D2セル =LET(r,VSTACK(A2:INDEX(A:A,MATCH(9^9,A:A)),B2:INDEX(B:B,MATCH(9^9,B:B))),o,SORT(UNIQUE(r,FALSE,TRUE)),HSTACK(IF(COUNTIF(A:A,o),o,""),IF(COUNTIF(B:B,o),o,"")))
 

<結果図>
行 ____A____ ____B____ _C_ _D_ _E_
 1 顧客番号  顧客番号             
 2       370       650         160
 3       250       490     360    
 4       146        47     370    
 5        47       250         450
 6       250       146         490
 7       650       160            
 8       360       450            

ありがとうございます。
でも、チョット私のレベルでは難しそうな気がしています。
若番順のソートは省略しても良いので、もう少し簡単は方法は無いでしょうか？
何なら、作業列を利用してもいいと思っています。

　　 A　　 B　　C　　　D　　　E　　F　　 G　　H
1　客番A 客番B　　　　　　　　　　　　　　　
2　　370　 650 TRUE　 FALSE　　　　　　　　
3　　250　 490 ↑A　　↑B　　　　　　　　　
4　　146　 47　　　　　　　　　　　　　　　
5　　47　　250　　　　　　　　　　　　　　　
6　　250　 146　　　　　　　　　　　　　　　
7　　650　 160　　　　　　　　　　　　　　　
8　　360　 450　　　　　　　　　　　　　　　
9　　　　　　　　　　　　　　　　　　　　　
10 客番A 客番B　　　客番A　 客番B　　　 値　客番枠
11　 370　 490　　　　　　　　160　　　 160　　　2
12　 360　 160　　　　360　　　　　　　 360　　　1
13　　　　 450　　　　370　　　　　　　 370　　　1
14　　　　　　　　　　　　　　450　　　 450　　　2
15　　　　　　　　　　　　　　490　　　 490　　　2
16
 
１．範囲 A1:B8 ⇒ A10:B16 への変換は、[フィルタオプションの設定]による。
￣￣範囲 C1:C2 ＆ D1:D2 はそのための[検索条件範囲]で、セル C2、C3 に入力式は
￣￣それぞれ、=COUNTIF(B$2:B$8,A2)=0、=COUNTIF(A$2:A$8,B2)=0
２．範囲 D10:E15 が最終結果であるが、その右欄の表は表 A11:B13 の数値を昇順に
￣￣並べ替えたり、格納場所を指定するための作業範囲です。
￣￣頗る愚直な方法なので初心者向けにはなるンじゃなかろうかと。(*^_^*)

E2セル =SMALL(A:B,SEQUENCE(COUNT(A:B)))
F2セル =UNIQUE(E2#,FALSE,TRUE)
C2セル =IF(COUNTIF(A:A,F2#),F2#,"")
D2セル =IF(C2#="",F2#,"")
 

<結果図>
行 ____A____ ____B____ _C_ _D_ _E_ _F_
 1 顧客番号  顧客番号                 
 2     370       650       160  47 160
 3     250       490   360      47 360
 4     146        47   370     146 370
 5      47       250       450 146 450
 6     250       146       490 160 490
 7     650       160           250    
 8     360       450           250    
 :      :         :             :
15                             650    

望み通りに結果が得られました。
 
お二方、ありがとうございました。
 
感謝致します。