HOME > Q&A > Excel （一般機能）

Excel （一般機能）
Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(指定なし : 指定なし)
フィルタ―下で、重複を除いてカウントしたい。
投稿日時: 23/06/07 14:00:25
投稿者: まさゆり

フィルタ―下で、
データ個数をカウントする場合は、「subtotal(3,範囲）」を利用しています。
 
一方、データ個数をカウントしたい場合、
重複する項目を一つとして、「subtotal」ではできない？ので、検索の結果、
「=SUMPRODUCT(1/COUNTIF(範囲,範囲))」でできました。
 
しかし、空白セルがあると「#DIV/0!]となってしまいます。
空白セルを含む範囲設定でも、カウントする方法があればお教え願えれば幸いです。
 
 
 例
A　 B　C
1　あ　2
2　い　4
3　う　5
4（空白）
5　お　4
6（空白）
 
合計　範囲　c2:c6　で、15　
個数　範囲　c2:c3　で、3 (「=SUMPRODUCT(1/COUNTIF(c1:c3,c1:c3))」
個数　範囲　c2:c6　で、#DIV/0!を回避して「3」としたい。
 
 
 
回答
投稿日時: 23/06/07 14:19:43
投稿者: んなっと

フィルターの記述を無視すると...
=COUNT(0/FREQUENCY(C1:C6,C1:C6))
回答
投稿日時: 23/06/07 14:20:31
投稿者: んなっと

Excelのバージョンは何ですか?
質問時に必ずExcelのバージョンを選んでください。
回答
投稿日時: 23/06/07 16:16:21
投稿者: んなっと

フィルターを考慮すると
 
=SUMPRODUCT(SUBTOTAL(2,INDIRECT("C"&ROW(2:7)))*(MATCH(C2:C7&"",C2:C7&"",0)=ROW(2:7)-1))
 
とか
 
=COUNT(0/FREQUENCY(IF(SUBTOTAL(2,INDIRECT("C"&ROW(2:7))),MATCH(C2:C7,C:C,0)),ROW(2:7)))
Ctrl+Shift+Enter同時押し
投稿日時: 23/06/07 18:23:53
投稿者: まさゆり

んなっと様
お世話になります。
 
・Excelバージョンは、2019 (MSO2304）です。（失礼しました。再ログイン時の失念でした。
 
・先の事例で一部範囲が（C2:C6 → C1:C6 ）間違っていました（再度お詫び申し上げます）
　お教えいただいた式をそのままセル C１（🔳）に入れても「０」となってしまいます。
　
　=SUMPRODUCT(SUBTOTAL(2,INDIRECT("C"&ROW(2:7)))*(MATCH(C2:C7&"",C2:C7&"",0)=ROW(2:7)-1))
 
 例
A　 B　C
1 ー　 🔳
2　あ　東京
3　い　品川
4 う　横浜
5 え　小田原
6 お　熱海
7　か　沼津
 
　式を選択すると「7行目まで "選択”」されてしまいますが、？
　二つ目の式も試してみましたが「０」でした。
　「Ctrl+Shift+Enter同時押し」の意味も不明でした
 
よろしくお願いします。

回答
投稿日時: 23/06/07 18:48:54
投稿者: んなっと

C列は数値ではなくて文字列なんですね。
 
　　　B　　 C　D
1　名前　終点　3
2　　あ　東京　　
3　　い　品川　　
4　　う　　　　　
5　　え　東京　　
6　　お　熱海　　
7　　か　　　　　
 
D1
=COUNT(0/FREQUENCY(IF(SUBTOTAL(3,INDIRECT("C"&ROW(2:7))),MATCH(C2:C7,C:C,0)),ROW(2:7)))
と入力したら、Ctrl,Shift,Enterの3つのキーを同時押し。

回答
投稿日時: 23/06/08 08:09:39
投稿者: んなっと

これもあるかも。
=COUNT(0/FREQUENCY(FILTER(MATCH(C2:C7,C:C,0),SUBTOTAL(3,INDIRECT("C"&ROW(2:7)))),ROW(2:7)))
Ctrl+Shift+Enter同時押し
 
あと、回答ではなくて質問があるのですが、
いいですか?
投稿日時: 23/06/10 17:18:03
投稿者: まさゆり

んなっと様
お世話になります。（返信の遅れ失礼しました）
 
紹介頂いたいずれの式も、なぜか上手くいきませんでした。
（操作不備があるかもしれません）
 
例で肝心な要件を失念しておりました。
各ｃ列の、1行目にカウント
2行目に名称にフィルター機能
（3〜5行目までフィルターをかけて）
6〜15行目まで、一部重複する名称と空白セル
 
以上です。
不足条件など、なんでも質問いただければと思います。
 
回答
投稿日時: 23/06/10 17:43:54
投稿者: んなっと

新規ブックで以下のように配置して
 
　　　B　　 C　D
1　名前　　値　
2　　あ　東京　　
3　　い　品川　　
4　　う　　　　　
5　　え　東京　　
6　　お　熱海　　
7　　か　　　　　
 
D1
=COUNT(0/FREQUENCY(IF(SUBTOTAL(3,INDIRECT("C"&ROW(2:7))),MATCH(C2:C7,C:C,0)),ROW(2:7)))
Ctrl+Shift+Enter同時押し
 
→D1に3が返ると思います
→B列にフィルターをかけてみましょう。例えば　あ、え、お　にチェック
 
　　　B　　 C　D
1　名前　　値　2
2　　あ　東京　　
5　　え　東京　　
6　　お　熱海　　
 
質問はまだです。とりあえず上の操作の結果を書き込んでください。
投稿日時: 23/06/14 23:05:55
投稿者: まさゆり

えなっと様
　今回も、なぜか D1に「０」が出てしまいましたが、
　落ち着いて操作したら、なぜかできました。
 
（過去にも助けていただいたことを覚えています）
大変助かりました。ありがとうございました。