HOME > Q&A > Excel （一般機能）

Excel （一般機能）
Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 11 Pro : Excel 2021)
複数条件でのフィルタ抽出
投稿日時: 23/06/05 18:52:00
投稿者: kou5355

お世話になります。
 
会社名    A担当　B担当　C担当
☓○産業　　井上　　田中　　山田
△☓産業　　山田　　井上　　松下
◎☓産業　　田中　　井上　　松下
●●産業　　松下　　山田　　田中
 
 
上記のような表がありまして、
「A担当、B担当、C担当　のいずれかに"田中"が含まれる
行だけを抽出したい」といったフィルタは可能でしょうか？
 
上記で言えば、2段目の「△☓産業」だけが非表示になるイメージです。
 
*目的は、田中くんに「自身の担当先一覧を出力して渡す」ためです。
（実現すれば、同様に井上くん、松下くんにも自身担当先一覧を渡します）
 
よろしくお願いいたします。
回答
投稿日時: 23/06/05 19:27:04
投稿者: んなっと

G1に田中
 
　　　　　A　　　B　　　C　　　D　E　F　　 G　　　　 H　　　I　　　J　　　K
1　　会社名　A担当　B担当　C担当　　　　田中　　会社名　A担当　B担当　C担当
2　×○産業　 井上　 田中　 山田　　　　　　　×○産業　 井上　 田中　 山田
3　△×産業　 山田　 井上　 松下　　　　　　　◎×産業　 田中　 井上　 松下
4　◎×産業　 田中　 井上　 松下　　　　　　　●●産業　 松下　 山田　 田中
5　●●産業　 松下　 山田　 田中　　　　　　　　　　　　　　　　　　　　　　
 
H2
=LET(x,A2:D100,y,ROW(x)/(x=G1),z,AGGREGATE(15,6,y,SEQUENCE(COUNT(y))),FILTER(x,ISNUMBER(XMATCH(ROW(x),z))))
回答
投稿日時: 23/06/05 19:43:35
投稿者: んなっと

365なら
=LET(x,A2:D100,FILTER(x,BYROW(x,LAMBDA(r,ISNUMBER(XMATCH(G1,r))))))
回答
投稿日時: 23/06/05 23:03:01
投稿者: Mike

　　 A　　　 B　　 C　　 D　 E　F　　G
1 会社名　 A担当 B担当 C担当
2 ×○産業 井上　田中　山田
3 △×産業 山田　井上　松下
4 ◎×産業 田中　井上　松下
5 ●●産業 松下　山田　田中
6　　　　　　　　　　　　　　　担当
7　　　　　　　　　　　　　　　田中 TRUE
 
セル G6 は空白のままに放置 ←コレ重要ｯ!
セル G7 に式 =OR(C3=G$8,D3=G$8,E$3=G$8) を入力
下記の作業を実行ｯ！(Excel 2019)
範囲 A1:D5 を選択⇒Alt+AQ⇒何やら警告メッセージが出ても“知らぬ存ぜぬ”の
一点張りで無視⇒[OK]⇒[フィルタオプションの設定]メニューにおいて、
[抽出先]として、“選択範囲内”に目玉入りを確認
[ﾘｽﾄ範囲]として $A$1:$D$5 が入力されていることの確認
[検索条件範囲]ボックス内にマウスカーソルを放り投げて、ワークシートの範囲
G6:G7 を撫で撫で(→ボックス内に $G$6:$G$7 が表示)⇒[OK]ボタンを「エイヤッ!」
と叩き付け
最終的に下記の姿が表示されててオ・シ・マ・イ
 
　　 A　　　 B　　 C　　 D　 E　F　　G
1 会社名　 A担当 B担当 C担当
2 ×○産業 井上　田中　山田
4 ◎×産業 田中　井上　松下
5 ●●産業 松下　山田　田中
6　　　　　　　　　　　　　　　担当
7　　　　　　　　　　　　　　　田中 TRUE
回答
投稿日時: 23/06/06 07:37:38
投稿者: んなっと

田中だけでなく、複数人の表を同じシート上に作るときは
 
　　　　　A　　　B　　　C　　　D　E　F　　 G　　　　 H　　　I　　　J　　　K　　 L　　　　 M
1　　会社名　A担当　B担当　C担当　　　　田中　　会社名　A担当　B担当　C担当　井上　　会社名
2　×○産業　 井上　 田中　 山田　　　　　　　×○産業　 井上　 田中　 山田　　　　×○産業
3　△×産業　 山田　 井上　 松下　　　　　　　◎×産業　 田中　 井上　 松下　　　　△×産業
4　◎×産業　 田中　 井上　 松下　　　　　　　●●産業　 松下　 山田　 田中　　　　◎×産業
5　●●産業　 松下　 山田　 田中　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　
 
H2
=LET(x,$A$2:$D$100,y,ROW(x)/(x=G1),z,AGGREGATE(15,6,y,SEQUENCE(COUNT(y))),FILTER(x,ISNUMBER(XMATCH(ROW(x),z))))
　としてから
→G1:K2をコピーして右方向に数回貼り付け
→田中を井上などに変更
投稿日時: 23/06/06 15:47:11
投稿者: kou5355

んなっと さんの引用:
田中だけでなく、複数人の表を同じシート上に作るときは
 
　　　　　A　　　B　　　C　　　D　E　F　　 G　　　　 H　　　I　　　J　　　K　　 L　　　　 M
1　　会社名　A担当　B担当　C担当　　　　田中　　会社名　A担当　B担当　C担当　井上　　会社名
2　×○産業　 井上　 田中　 山田　　　　　　　×○産業　 井上　 田中　 山田　　　　×○産業
3　△×産業　 山田　 井上　 松下　　　　　　　◎×産業　 田中　 井上　 松下　　　　△×産業
4　◎×産業　 田中　 井上　 松下　　　　　　　●●産業　 松下　 山田　 田中　　　　◎×産業
5　●●産業　 松下　 山田　 田中　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　
 
H2
=LET(x,$A$2:$D$100,y,ROW(x)/(x=G1),z,AGGREGATE(15,6,y,SEQUENCE(COUNT(y))),FILTER(x,ISNUMBER(XMATCH(ROW(x),z))))
　としてから
→G1:K2をコピーして右方向に数回貼り付け
→田中を井上などに変更

 
 
ありがとうございました。解決いたしました。