スキルアップ・問題解決なら、モーグにおまかせ！

エクセル初心者でいろいろ調べているのですが、応用なのか、なかなか苦戦しています。
 
 
表�@の中に[ a 〜 k ]の文字があります。
表�@にある文字が表�Aの中にあるのかを調べ、また無かった時は、なにが無いのかを表示したいです。
 
条件：１　表�Aには[ a 〜 k ] の文字がすべてあるものとします。
　　　２　無かった文字を表示する場所は【B１３】とします。
 
　　　　A 　B　C　D　E
　　１　　　a 　　a
　　２　　　b　 　b
　　３　　　c
　　４　　　d 　　d
　　５　　　e 　　e
　　６　　　f 　
　　７　　　g 　　g
　　８　　　h 　　h
　　９　　　i 　　i
　１０　　　j
　１１　　　k　 　k
　１２
　１３　　
 
   B＝表�@
   D＝表�A
 
　よろしくお願いいたします。

●同じ行に同じ文字であれば
  
　　　　B　C　D
 1　　　a　　 a
 2　　　b　　 b
 3　　　c　　　
 4　　　d　　 d
 5　　　e　　 e
 6　　　f　　　
 7　　　g　　 g
 8　　　h　　 h
 9　　　i　　 i
10　　　j　　　
11　　　k　　 k
12　　　　　　　
13　c,f,j　　　
14　　f,j　　　
15　　　j　　　
 
B13
=IFERROR(INDEX(B$1:B$11,AGGREGATE(15,6,ROW($1:$11)/(D$1:D$11=""),ROW(B1))),"")&IF(B14="","",","&B14)
下方向・↓　14行から下の数行を非表示に
  
最新のExcelなら
B13
=TEXTJOIN(",",,FILTER(B1:B11,D1:D11=""))
  
  
●行がバラバラであれば
  
　　　　B　C　D
 1　　　a　　 e
 2　　　b　　 g
 3　　　c　　 d
 4　　　d　　 a
 5　　　e　　 k
 6　　　f　　 b
 7　　　g　　　
 8　　　h　　　
 9　　　i　　 i
10　　　j　　 h
11　　　k　　　
12　　　　　　　　　　　　
13　c,f,j　　　
14　　f,j　　　
15　　　j　　　
 
B13
=IFERROR(INDEX(B$1:B$11,AGGREGATE(15,6,ROW($1:$11)/(ISNA(MATCH(B$1:B$11,D$1:D$11,0))),ROW(B1))),"")&IF(B14="","",","&B14)
下方向・↓　14行から下の数行を非表示に
  
最新のExcelなら
B13
=TEXTJOIN(",",,FILTER(B1:B11,COUNTIF(D1:D11,B1:B11)=0))
  
※質問時にExcelのバージョンを選択してください。

　ありがとうございます。無事解決しました。
 
　今後バージョン指定と分かりやすい説明できるようにします>_<