スキルアップ・問題解決なら、モーグにおまかせ！

シート1のE3以降に数式を入れて反映させたいです。
シート2の"a"のみかんとR1の交差するところに○があったらシート1のE3に○を表示します。
お手数おかけしますがよろしくお願いいたします。
 
シート1
　　A　B　C　D　E　  F  　G 　H　  I　   J
1　 　 　 　　　　　みかん　　　りんご
2　  　　　　　 　R1   R2   R3　R1　R2　R3
3　a　　　　　　 ○　　　　　○
4　b　　　　　　　　　　　　　　　　  ○
5　c
 
シート2
　　A　B　C　D　　E　　 　 F
1　　　　　　　　みかん　りんご
2
3　a　R1  　　　  　 ○　　　○
4　b　R3　　　　　　　　　 ○
5　c　R5　　 　　　○　　　
6　d　R4
7　e　R3　　　　　　　　　  ○

　 A　B　C　D　　　 E　 F　 G　　　 H　 I　 J
1　　　　　　　みかん　　　　　りんご　　　　
2　　　　　　　　　R1　R2　R3　　　R1　R2　R3
3　a　　　　　　　 ○　　　　　　　○　　　　
4　b　　　　　　　　　　　　　　　　　　　 ○
5　c　　　　　　　　　　　　　　　　　　　　　
 
E3
=IFERROR(XLOOKUP($A3&"|"&E$2,シート2!$A$1:$A$200&"|"&シート2!$B$1:$B$200,XLOOKUP(LOOKUP("ーー",$E$1:E$1),シート2!$1:$1,シート2!$1:$200)&"",""),"")
右方向・→下方向・↓

ほかにも。
=LET(a,シート2!$1:$200,IFERROR(XLOOKUP($A3&"|"&E$2,BYROW(TAKE(a,,2),LAMBDA(r,TEXTJOIN("|",,r))),XLOOKUP(LOOKUP("ーー",$E$1:E$1),TAKE(a,1),a)&"",""),""))

ありがとうございます。大変助かります。
"|"やーー"の意味はなんでしょうか？調べても出てこず…
 
=IFERROR(XLOOKUP($A3&"|"&E$2,シート2!$A$1:$A$200&"|"&シート2!$B$1:$B$200,XLOOKUP(LOOKUP("ーー",$E$1:E$1),シート2!$1:$1,シート2!$1:$200)&"",""),"")
 

　|　...使われない文字であれば何でもいいです。今回はなくても大丈夫です。
$A3&E$2だと、次の2組がどちらも同じになってしまうが、
 
　 a　R1　　aR1
　aR　 1　　aR1
 
$A3&"|"&E$2なら区別できる。
 
　 a　R1　　a|R1
　aR　 1　　aR|1
 
XLOOKUP(1,(シート2!$A$1:$A$200=$A3)*(シート2!$B$1:$B$200=E$2)...の形でもOKです。
 
 
 
LOOKUP("ーー",範囲)...範囲の最後の文字列(数値は除く)を取得したいときに使います。
例えば下のA1:A10の範囲の最後の文字　龍　を知りたいときは、=LOOKUP("ーー",$A1:$A10)
 
　　 A
 1　　
 2　い
 3　 A 　←=LOOKUP("舘",$A1:$A10)はAになってしまって失敗
 4　　
 5　々
 6　　
 7　龍 　←=LOOKUP("ーー",$A1:$A10)
 8　　
 9　　
10　　
 

=XLOOKUP("?*",$A1:$A10,$A1:$A10,"",2,-1)　のような形でもいいかもしれません。

とても勉強になりました。
ありがとうございました。