スキルアップ・問題解決なら、モーグにおまかせ！

おつかれさまです
 
以下のコードは現象を再現するためのわざとらしいものです。
いままでも同じようなコーディングはしていたように思いますが
(たぶん)、Static の挙動はこのようなものなのでしょうか。
 

Public Sub Test()

    Dim ast()   As String   ' Array of string
    Dim i       As Long
    
    ast = GetSameArrayAnytime()
    For i = LBound(ast) To UBound(ast)
        Debug.Print ast(i)
    Next i
    
    ast = GetSameArrayAnytime()
    For i = LBound(ast) To UBound(ast)  ' (9) インデクスが有効範囲にありません
        Debug.Print ast(i)
    Next i

End Sub

' 毎回同じ配列を返す
Private Function GetSameArrayAnytime() As String()

    Static ast()    As String
    Static bInit    As Boolean
    
    If (Not bInit) Then
        ast = GetArray()    ' ast は一度だけ初期化される
        bInit = True
    End If

    GetSameArrayAnytime = ast

End Function

' 初期化のため一度だけ呼ばれる
Private Function GetArray() As String()
    
    Dim ast(1 To 3) As String
    
    ast(1) = "a"
    ast(2) = "b"
    ast(3) = "c"
    
    GetArray = ast

End Function

a
b
c
a
b
c

2回目でもう一度代入しようとしているからでは？

Public Sub Test()

    Dim ast()   As String   ' Array of string
    Dim i       As Long
    
    ast = GetSameArrayAnytime()
    For i = LBound(ast) To UBound(ast)
        Debug.Print ast(i)
    Next i
    
'    ast = GetSameArrayAnytime()
    For i = LBound(ast) To UBound(ast)  ' (9) インデクスが有効範囲にありません
        Debug.Print ast(i)
    Next i

End Sub

あ、そういうことじゃないよってことであれば、無視してください。

taitani さん、
レスをありがとうございます。
 
先ほどのプロシジャ Test をもう少し実際に近づけると
次のようになります：
 

Public Sub Test_2()

    Call CalledManyTimes

    ' Do something

    Call CalledManyTimes

End Sub

' 何回も呼ばれる処理
Public Sub CalledManyTimes()

    Dim ast()   As String   ' Array of string
    Dim i       As Long
    
    ast = GetSameArrayAnytime()
    For i = LBound(ast) To UBound(ast)
        Debug.Print ast(i)
    Next i

End Sub

うーん、私的に違和感がありますね。
 
Dim ast() As String と Static ast() As String が。
 
Static は、実行するたびに、変動する (させる) 変数なので、

引用:
何度も呼ばれる処理で、つねに同一の配列を得る目的です。

＞(たぶん)、Static の挙動はこのようなものなのでしょうか。
いやー、Staticだから、エラーになるのはおかしいでしょうね。
 
いろいろ実験してみると驚き
　↓
' 毎回同じ配列を返す
Private Function GetSameArrayAnytime() As String()
 
    Static ast() As String
    Static bInit As Boolean
     
    If (Not bInit) Then
        ast = GetArray() ' ast は一度だけ初期化される
        bInit = True
    End If
 
    GetSameArrayAnytime = ast
    Debug.Print UBound(ast)　　’←★ここにこの詰まんないステートメントを1文
　　　　　　　　　　　　　　　 ’入れるだけでトラブらなくなる
End Function

taitani さん、
引き続きありがとうございます。
 
ちょっとタイトルが不適切だったかもと感じていまして、
元々いいたかったことは「Static な配列の挙動」に
ついてのことでした。
Static の挙動については理解しているつもりです(たぶん)。
 
よく GetArray() (のようなプロシジャ)で DBから情報を
抽出して返すようなことをするのですが、配列より
Dictionary を使用することが多かった気がします。
 

Function GetDic(ByBal key_ As String) As Scripting.Dictionary

    Static dic As Scripting.Dictionary

    if dic is Nothing Then
        set dic = new Scripting.Dictionary
        ' 登録処理
    Enf if
    
    set GetDic = dic

End function

＞半平太 さんの環境でも、元のコードでは同様の現象が発生した
＞のでしょうか(のですよね)。
 
こちらも同様の現象が発生したんです。
 
理屈からするとおかしいので、一般ユーザーレベルではバグと言うしかないです。
 
まともな対策(解消方法)が何か分からないですが、先の実験からの推測だと、
配列待遇のコードを入れればいいのかなぁと漠然と思っていますけど。
 
流石にdebug.print なんて書くのはみっともないので、
こんな風にカモフラージュしたら(★)？　これでもトラブらなかったですけど。
　　↓
' 毎回同じ配列を返す
Private Function GetSameArrayAnytime() As String()
 
    Static ast() As String
    Static bInit As Boolean
     
    If (Not bInit) Then
        ast = GetArray() ' ast は一度だけ初期化される
        bInit = True
    End If
 
    If IsArray(ast) Then　’★
        GetSameArrayAnytime = ast
    End If
     
 
End Function

動的配列をStatic(静的)宣言するのがちょっと違和感があります。
 
Static ステートメント (VBA) | Microsoft Learn
https://learn.microsoft.com/ja-jp/office/vba/language/reference/user-interface-help/static-statement
上記の公式ドキュメントには下記の記述があります。
プロシージャ レベルで 変数を宣言し 、記憶域 スペース を割り当てる場合に使用します。 Static ステートメントで宣言された変数は、コードが実行されている間はその値を保持します。
 
宣言時にはサイズが決まっていないものの「記憶域 スペース を割り当てる」というのは矛盾している感じがします。
 
そこで下記のように Variant で宣言してみたらうまくいきました。
 

' 毎回同じ配列を返す
Private Function GetSameArrayAnytime() As String()

    Static ast   As Variant ' ★
    Static bInit    As Boolean
    
    If (Not bInit) Then
        ast = GetArray()    ' ast は一度だけ初期化される
        bInit = True
    End If

    GetSameArrayAnytime = ast

End Function

半平太 さん、
ありがとうございます。
 
しかし、いろいろなアイデアを思いつくものですね…
 
ちなみに、一つ前の僕のレスの GetDic()の例は問題なしです。
 
 
大変申し訳無いのですが、明日は時間を取ることができないため、
返信ができないかもしれません。
 
 
と、返信しようとしたところで、
 
hatena さん
ありがとうございます。
 
Static変数は BSSに、動的な配列の場合は LPSAFEARRAY
(VBの配列へのポインタ。固定サイズ)が配置され、配列自体は
ヒープに動的に確保されるのかなと。(嘘ですたぶん!!)
 
Dictionaryへの参照(ポインタ)は OKですし…

＞動的配列をStatic(静的)宣言するのがちょっと違和感があります
 
との事ですが、マイクロソフトの別の記述によると
　　　　　　　　　↓
　　　　　【配列を宣言する】
https://learn.microsoft.com/ja-jp/office/vba/language/concepts/getting-started/declaring-arrays
＞動的配列を宣言すると、コードの実行中に配列のサイズを変更できます。
＞次の例に示すように、Static、Dim、Private、または Public ステートメントを使用し、
＞配列を宣言します。かっこ内は空にしてください。
 
となっていますので、Staticでも動的配列は普通のことと思えます。
 
＞関数の引数にすると「記憶域 スペース」確保することができるということになるのでしょうか。
 
この解釈が正しいとすれば、一回でも確保すればいいハズですが(Staticなので）、
実験してみると、GetSameArrayAnytimeへ代入する前に関数の引数にしても効果はありません。
 
' Debug.Print UBound(ast) 　　'★１ここにだけ入れても、トラブル
    GetSameArrayAnytime = ast
' Debug.Print UBound(ast) 　　'★２ここに入れるだけで、ノントラブル
 
私の結論としては、Staticの属性を失念してしまうプロシージャ解析プログラムの
バグと思います。

現時点での結論としては「 VBA のバグの一種である」可能性が
高いように思われますけど。
 
まず件のプロシージャについて。
 

たらのり さんの引用:
Private Function GetSameArrayAnytime() As String()
 
    Static ast() As String
    Static bInit As Boolean
     
    If (Not bInit) Then
        ast = GetArray() ' ast は一度だけ初期化される
        bInit = True
    End If
 
    GetSameArrayAnytime = ast
 
End Function

たらのり さんの引用:
Public Sub Test()
 
    Dim ast() As String ' Array of string
    Dim i As Long
     
    ast = GetSameArrayAnytime()
    For i = LBound(ast) To UBound(ast)
        Debug.Print ast(i)
    Next i
     
    ast = GetSameArrayAnytime()
    For i = LBound(ast) To UBound(ast) ' (9) インデクスが有効範囲にありません
        Debug.Print ast(i)
    Next i
 
End Sub

半平太 さんの引用:
GetSameArrayAnytime = ast
Debug.Print UBound(ast)　　’←★ここにこの詰まんないステートメントを1文

hatena さんの引用:
そこで下記のように Variant で宣言してみたらうまくいきました。

hatena さんの引用:
Static ast As Variant ' ★
Static bInit As Boolean

さすがskさん、緻密な分析。
 

引用:
なんと適当に行ラベルを挿入するだけでも有効。

ちょっといたずらで、Static の領域がどうなっているのか、
DLLを書いて表示してみました。
 
# 久々の Windowsプログラムなので、変なところもあるかと
 

' VBA
Private Declare PtrSafe Sub DumpMem _
        Lib "C:\Users\user\dev\dll\test\PeekStatic.dll" _
        (ByVal p As LongPtr, ByVal sz As Long)

Public Sub Test()

    Dim ast()   As String
    Dim i       As Long
    
    ast = GetSameArrayAnytime()
    For i = LBound(ast) To UBound(ast)
        Debug.Print ast(i)
    Next i
    
    ast = GetSameArrayAnytime()
    For i = LBound(ast) To UBound(ast)  ' * (9) インデクスが有効範囲にありません
        Debug.Print ast(i)
    Next i

    End
End Sub

' 毎回同じ配列を返す
Private Function GetSameArrayAnytime() As String()

    Static dummy    As Long
    Static ast()    As String   ' Array of string
    Static bInit    As Boolean
    
    Call DumpMem(VarPtr(dummy), 16)     ' ★ DLL呼び出し
    
    If (Not bInit) Then
        
        dummy = &HAAAAAAAA
        ast = GetArray()    ' ast は一度だけ初期化される
        bInit = True
    End If
    
    Call DumpMem(VarPtr(dummy), 16)     ' ★ DLL呼び出し

    GetSameArrayAnytime = ast           ' ☆
    
''  Call DumpMem(VarPtr(dummy), 16)     ' ★★ DLL呼び出し(しない)

End Function

' 初期化のため一度だけ呼ばれる
Private Function GetArray() As String()
    
    Dim ast(1 To 3) As String
    
    ast(1) = "a"
    ast(2) = "b"
    ast(3) = "c"
    
    GetArray = ast

End Function

/* peekstatic.c */
#include <windows.h>
#include <stdio.h>

void WINAPI DumpMem(const char *p, int sz)
{
    char *buf;
    int i;

    buf = (char *) malloc(sz * 3 + 1);
    if (!buf) {
        MessageBox(NULL, "malloc() error.", "DLL", MB_OK | MB_ICONERROR);
        return;
    }

    if (!p) {
        MessageBox(NULL, "Argment is NULL.", "DLL", MB_OK | MB_ICONERROR);
        return;
    }

    for (i = 0; i < sz; i++) {
        sprintf(buf + i * 3, "%02X,", p[i] & 0xff);
    }
    buf[sz * 3] = '\0';

    MessageBox(NULL, buf, "DLL", MB_OK | MB_ICONINFORMATION);

    free(buf);

    return;
}

; peekstatic.def
LIBRARY PeekStatic

EXPORTS
    DumpMem

1回目の呼び出し
00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,    … 初期化前
AA,AA,AA,AA,**,**,**,**,**,**,**,**,FF,FF,00,00,    … 初期化後

2回目の呼び出し
AA,AA,AA,AA,00,00,00,00,00,00,00,00,FF,FF,00,00,    … ast 域が、、、
AA,AA,AA,AA,00,00,00,00,00,00,00,00,FF,FF,00,00,

こんにちは
 
自宅には実行環境がないのでテストできませんが、
1回めの呼び出し時にモジュールレベルの変数などに
Static領域(dummy)のアドレスを保持しておいて
呼び出しから戻った直後に DumpMem() で覗いて
みればよかったなと。
 
でも今回はここまでにしておきます。
 
# もしかしたら、テスト結果を年明けに給湯室で
 
 
いつもはこのようなときに Scripting.Dictionaryを
使用することが多いといいましたが、今回は順序を
維持したいために配列を使用しました。
が、Collectionがその目的に合うことを知り、
今回の問題を解決することができました。
 
ずーっと存在は知っていた Collection。
なぜか使ったことがなかったのですが、なかなか
使い勝手がよさそうです(20年気づくのが遅かった…)。
 
 
レスをくださった
taitani さん
半平太 さん
hatena さん
sk さん
ありがとうございました。
 
皆さま よいお年をお迎えください。