スキルアップ・問題解決なら、モーグにおまかせ！

ユーザーフォームをアクティブセルの近くに（上に）表示したいのですが、どのようにしてTOP、LEFTの値を得ればいいでしょうか？

Sub SelectionShow()
    Dim xAdd   As Long
    Dim yAdd   As Long
    Dim StrTmp As String
    Dim TagRng As Range
    Dim TagAdr As String
    
    StrTmp = Selection.Address
    If InStr(StrTmp, ":") = 0 Then
        TagAdr = StrTmp
    Else
        TagAdr = Mid(StrTmp, InStr(StrTmp, ":") + 1, Len(StrTmp) - InStr(StrTmp, ":"))
    End If
    
    Set TagRng = Range(TagAdr).Offset(1, 1)
    
    xAdd = ActiveWindow.PointsToScreenPixelsX(0) * 72 / 96 + TagRng.Left * ActiveWindow.Zoom / 100
    yAdd = ActiveWindow.PointsToScreenPixelsY(0) * 72 / 96 + TagRng.Top * ActiveWindow.Zoom / 100
    
    Load UserForm1
    
    With UserForm1
        .StartUpPosition = 0
        .Left = xAdd
        .Top = yAdd
    End With
    
    UserForm1.Show

End Sub

こんにちは。
 
Private Sub UserForm_Initialize()
    Dim dblX As Double, dblY As Double
    With ActiveWindow
        dblX = .PointsToScreenPixelsX(0) / 96 * 72 + ActiveCell.Left * .Zoom / 100
        dblY = .PointsToScreenPixelsY(0) / 96 * 72 + ActiveCell.Top * .Zoom / 100
    End With
    With Me
        .StartUpPosition = 0
        .Left = dblX
        .Top = dblY
    End With
End Sub

taitaniさん、たかさん@富山さんありがとうございました、実行し確認できました。
参考にさせていただき勉強頑張ります。