スキルアップ・問題解決なら、モーグにおまかせ！

お世話になります。まだまだACCESS初心者です。
以下のコードで３点ご教示いただきたく、よろしくお願いいたします。
 
(1)※1のところで、rsとrstを使いまわしていますが、これはあまり良くないでしょうか。
　 正しいコードは別のレコードセットを宣言して使う、でしょうか。
　
(2)エラー処理を確認する為、※2で、「T_Table!社員コード」を「T_Table!社員コ」にした時、
　 ※3の「rst.Close」で「このコンテキストで操作は許可されていません」とエラーが出ます。
　 rstはopen状態なのにcloseできないのですが、どうしたら良いでしょうか。
　
(3)変数の付け方やロジックの書き方など、こういうのが慣例だよ、があれば
　 ご教示いただけると助かります。
　
　
お手数をおかけして申し訳ありませんが、どうぞよろしくお願いいたします。
 
 
===========================================================================
Private Sub cmdRegist_Click()
    Dim CN As New ADODB.Connection
    Dim rs As New ADODB.Recordset
    Dim rst As New ADODB.Recordset
     
On Error GoTo RegistError
 
    Set CN = CurrentProject.Connection
    CN.CursorLocation = adUseClient
     
    Set rs = New ADODB.Recordset
    Set rst = New ADODB.Recordset
     
    rs.Open "T_test1", CN, adOpenKeyset, adLockOptimistic
    rst.Open "T_test2", CurrentProject.Connection, , adLockOptimistic
     
    Do Until rs.EOF
  
        Call RegistTest(rst, rs!社員コード.Value)    
        rs.MoveNext
         
    Loop
 
    rs.Close
    rst.Close
     
    rs.Open "T_test3", CurrentProject.Connection '※1
    rst.Open "T_test4", CurrentProject.Connection, , adLockOptimistic
 
    Do Until rs.EOF
     
        処理
        rs.MoveNext
 
    Loop
 
    GoTo EndProc
     
    Exit Sub
'-----------------------------------------------------------------------------
RegistError:
 
    MsgBox Err.Description, vbCritical, strMsgTitle
 
     
EndProc:
    If rs.State = adStateOpen Then rs.Close: Set rs = Nothing
    If rst.State = adStateOpen Then rst.Close: Set rst = Nothing '※3
    CN.Close: Set CN = Nothing
     
End Sub
 
'************************************************************************
Private Sub RegistTest(T_Table As ADODB.Recordset, strEmpCode As String)
 
    T_Table.AddNew
    T_Table!社員コード = strEmpCode        '※2
    T_Table.Update
 
End Sub
 
===========================================================================
 

引用:
(1)※1のところで、rsとrstを使いまわしていますが、これはあまり良くないでしょうか。
　 正しいコードは別のレコードセットを宣言して使う、でしょうか。

引用:
(2)エラー処理を確認する為、※2で、「T_Table!社員コード」を「T_Table!社員コ」にした時、
　 ※3の「rst.Close」で「このコンテキストで操作は許可されていません」とエラーが出ます。

引用:
T_Table.AddNew
T_Table!社員コード = strEmpCode '※2
T_Table.Update

Microsoft さんの引用:
即時更新モードの間に編集が進行中の場合、Close メソッドを呼び出すとエラーが生成されます。
その代わりに、最初に Update または CancelUpdate メソッドを呼び出してください。

引用:
(3)変数の付け方やロジックの書き方など、こういうのが慣例だよ、があれば
　 ご教示いただけると助かります。

sk 様
早々のご教示をありがとうございます。m(__)m
 

引用:
一般論としての話なら「場合によるので正解はない」、
例示されたコードに関しての話なら「処理の結果や
ロジックに影響しないならどっちでもいい」という
回答になります。

引用:
AddNew メソッドが呼び出された後、その直後のステートメントを
実行しようとした際に実行時エラーが発生したことにより
Update メソッドが呼び出されぬままプロシージャを抜け、
更にその状態のまま Close メソッドを呼び出そうとしたためです。

引用:
その代わりに、最初に Update または CancelUpdate メソッドを呼び出してください。

引用:
コーディング全般の話としてなら、その手の話題は宗教論争になりかねませんので
「とりあえず『リーダブルコード』でも読みなはれ」という提案に留めておきます。

引用:
例示されたコードに関して言えば、いくつか修正の余地があるでしょう。

引用:
Private Sub RegistTest(T_Table As ADODB.Recordset, strEmpCode As String)
   
    T_Table.AddNew
    T_Table.Update
    T_Table!社員コード = strEmpCode '※2
    T_Table.Update
   
End Sub

引用:
EndProc:
    If rs.State = adStateOpen Then rs.Close: Set rs = Nothing
    If rst.State = adStateOpen Then rst.Close: Set rst = Nothing

sk 様
 
早々のご回答をありがとうございます!
そしてご親切に詳細なご説明を本当にありがとうございます。勉強になります。
会社の環境でないと確認できないため、月曜日に結果をご報告させていただきます。
まずはお礼まで。。。

提示されているVBAコードを見る限りでは
  
処理
 
の部分がブラックボックスになっていて怪しさを醸し出してるのですが
いかがでしょうか。

rose11 さんの引用:

(3)変数の付け方やロジックの書き方など、こういうのが慣例だよ、があれば
　 ご教示いただけると助かります。

Option Explicit

Const msEmployeeCode    As String = "社員コード"
Const tbTable1          As String = "T_test1"
Const tbTable2          As String = "T_test2"
Const tbTable3          As String = "T_test3"
Const tbTable4          As String = "T_test4"

Private Sub cmdRegist_Click()
    RegistNewRecord
End Sub

Private Sub RegistNewRecord()
'新規レコード登録
    Dim CN As New ADODB.Connection
    Dim strErrorMessage As String
        
    On Error GoTo ErrorTrap
    
    strErrorMessage = ""
    Set CN = CurrentProject.Connection
    CN.CursorLocation = adUseClient
    
    CN.BeginTrans
    
    strErrorMessage = AddRecordAtoB(tbTable1, tbTable2, CN)
    If strErrorMessage <> "" Then GoTo ErrorTrap
    
    strErrorMessage = AddRecordAtoB(tbTable3, tbTable4, CN)
    If strErrorMessage <> "" Then GoTo ErrorTrap
    
    CN.CommitTrans
    CN.Close
    Set CN = Nothing
    Exit Sub

ErrorTrap:
    If strErrorMessage = "" Then
        MsgBox Err.Description, vbCritical
    Else
        MsgBox strErrorMessage, vbCritical
    End If
        
    CN.RollbackTrans
    CN.Close
End Sub

Private Function AddRecordAtoB(strTableA As String _
                             , strTableB As String, CN As ADODB.Connection) As String
'レコード追加 A⇒B
'成功時は""を返す。エラー時はエラーメッセージを返す。
    Dim rsA As New ADODB.Recordset
    Dim rsB As New ADODB.Recordset
    Dim strEmployeeCode As String

    On Error GoTo ErrorTrap

    Set rsA = New ADODB.Recordset
    Set rsB = New ADODB.Recordset

    rsA.Open strTableA, CN, adOpenKeyset, adLockOptimistic
    rsB.Open strTableB, CurrentProject.Connection, , adLockOptimistic

    Do Until rsA.EOF
       strEmployeeCode = rsA.Fields(msEmployeeCode).Value
       With rsB
            .AddNew
            .Fields(msEmployeeCode) = strEmployeeCode
            .Update
        End With
        rsA.MoveNext
    Loop

    rsA.Clone
    rsB.Clone
    Set rsA = Nothing
    Set rsB = Nothing

    AddRecordAtoB = ""
    Exit Function

ErrorTrap:
    rsA.Close
    rsB.Close
    Set rsA = Nothing
    Set rsB = Nothing

    AddRecordAtoB = Err.Description
End Function

sk 様
 
返信が遅くなり申し訳ございませんでした。
ご教示いただきました方法でうまくいきました!
早々に色々とご教示いただきまして、本当にありがとうございました。
助かりましたm(_ _)m

ﾆｬｯﾁｭ 様
 
コメントをありがとうございます。
「処理」の部分は問題がないため、割愛させていただきました次第でした。
分かりづらい表現で失礼いたしました。m(_ _)m

sk 様
 
貴重なお時間を使ってご教示いただき、本当にありがとうございました!m(_ _)m

MMYS 様
 
ご教示をありがとうございます。
まさに私に足りないところだと思いました。
詳細なロジックをご提示いただき、解りやすいですし、
また要点も記載いただき、これから何に気を付ければ良いかが理解できるので助かります。
 
貴重なお時間を使ってのご教示、本当にありがとうございました!m(_ _)m