スキルアップ・問題解決なら、モーグにおまかせ！

VBA超初心者です。
エクセルの色付きセルを含む行のみ抽出し、別シートにコピーしたいのですが、ネットを検索してもセルのみの抽出・コピーしか探せませんでした。。
しかもセルのみの抽出・コピーもなぜかうまくいきません。TEST用エクセルでは動くのですが、本番用のものでは動きません。（エラーも出ません）
Sheet1はA4-O999までの表で、L、M、N、O列に色付きセルが発生します。（エクセル関数を入力、条件付き書式にて色付け設定、重複行で色付き発生は無し）
L、M、N、O列のいずれかのセルが黄色になったら行ごとコピーしてSheet2に貼り付けたいです。
コードについてご教示頂けませんでしょうか。
 
Sub Macro1()
'
' Macro1 Macro
'
 
Dim Sh1 As Worksheet
Dim Sh2 As Worksheet
Dim LastRow As Long
Dim i As Long
Dim j As Long
    
    j = 2
 
    Set Sh1 = Sheets("Sheet1")
    Set Sh2 = Sheets("Sheet2")
 
    '最終行を取得
    LastRow = Sh1.Cells(Rows.Count, 1).End(xlUp).Row
 
    'セルをループして黄色だったら、Sheet2へ転記
    For i = 5 To LastRow
        If Sh1.Cells(i, 12).Interior.Color = 65535 Then
            Sh1.Cells(i, 12).Copy Sh2.Cells(j, 1)
            j = j + 1
        End If
    Next i
 
    Set Sh1 = Nothing
    Set Sh2 = Nothing
 
End Sub

まず最初に
条件付き書式の機能を理解することです。
 
「条件付き」とは、
条件を指定するには、数式を使います。
その条件に合致した時だけ、書式（今回の場合、黄色の塗りつぶし）が反映されます。
 
従って、塗りつぶし＝黄色で判断しても、それは「条件付き書式」の色とは違います。
 
取り敢えず、
色で判定するのではなく、
そのセルに設定したある数式と同じ条件で判定するに変更してみてください。

追加レス
 
> Sh1.Cells(i, 12).Copy Sh2.Cells(j, 1)
 
このコードは、書式だけではなくすべて複写になってしまいますが
よいのですか？

追加の質問
 
>L、M、N、O列のいずれかのセルが黄色になったら行ごとコピーしてSheet2に貼り付けたいです。
と書いてありますが
コードを見ると
「L、M、N、O列のいずれかのセル」が、Ｌしか判断していないこと。
「行ごとコピー」が一つのセルだけになっていること
（Sheet1のＬ列セルだけをSheet2のＡ列に複写する）
 
確認したほうがよいですね？
 

ご指摘のとおり、条件に遡って、条件で判定する方法もあります。
 
また、次のような方法もあります。

If Sh1.Cells(i, 12).Interior.Color = 65535 Then

If Sh1.Cells(i, 12).DisplayFormat.Interior.Color = 65535 Then

simleさんレスをお借りして
色判定関数を紹介します。
「行」のＬ〜Ｏ列セルを指定して、いづれかが条件付き書式の色が黄色だったら、Trueで返る
 

Function 色判定(ByVal MyRNG As Range)
Dim mFC As FormatCondition, Fx As Long, mRg As Range
Const 黄色 = vbYellow

色判定 = False
For Each mRg In MyRNG  'L,M,N,O
    If mRg.DisplayFormat.Interior.Color = 黄色 Then
        If mRg.FormatConditions.Count > 0 Then
            For Fx = 1 To mRg.FormatConditions.Count
                Set mFC = mRg.FormatConditions(Fx)
                If mFC.Interior.Color = 黄色 Then
                    Debug.Print "条件付き書式の背景色=黄色の条件：" & mFC.Formula1
                    色判定 = True
                End If
            Next
        End If
    End If
Next
End Function

こういうことでしょうか。参考にしてください。
（不明点あれば、具体質問してください。）
 

Sub test()
    Dim sh1 As Worksheet, sh2 As Worksheet
    Dim lastRow As Long
    Dim i As Long
    Dim j As Long

    Application.ScreenUpdating = False

    Set sh1 = Worksheets("Sheet1")
    Set sh2 = Worksheets("Sheet2")

    lastRow = sh1.Cells(Rows.Count, "A").End(xlUp).Row
    j = 1
    For i = 5 To lastRow
        If check(sh1.Cells(i, "L").Resize(, 4)) Then
            sh1.Rows(i).Copy
            sh2.Cells(j, 1).PasteSpecial Paste:=xlPasteValues
            sh2.Cells(j, 1).PasteSpecial Paste:=xlPasteFormats
            j = j + 1
        End If
    Next
    Application.CutCopyMode = False
    Application.ScreenUpdating = True
End Sub

Function check(rng As Range) As Boolean
    Dim r As Range
    For Each r In rng
        If r.DisplayFormat.Interior.Color = vbYellow Then
            check = True
            Exit Function
        End If
    Next
End Function

WinArrowさん、Simpleさん、ご親切にありがとうございました。
お返事が遅くなり申し訳ございません。コードをご教示頂いたとおりに修正したら期待通りの結果を得ることができました。
大変助かりました。またご質問させていただくことがあると思いますが、どうぞよろしくお願いいたします。
 :D