Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 10 Pro : Excel 2021)
複数の条件に合致するものの隣のセルの値を抽出したい
投稿日時: 22/08/08 02:09:30
投稿者: 55taru

初心者ですみません、教えてください。
複数の条件に合致するものの隣のセルの値を抽出したいのです。
シート1に
No    名前    金額A    金額B    日付
1    Aさん    100    9000    4月1日
2    Bさん    200    8000    4月1日
3    Cさん    300    7000    4月1日
4    Dさん    100    6000    4月1日
1    Aさん    500    1000    5月1日
2    Bさん    900    2000    5月1日
 
とあります。
シート2に
No    名前    日付    金額A
1    Aさん    5月1日    
 
とあり、金額A にあたる 500 と抽出したいのですが
INDEX MATCH ?
IF AND ?
DGET ?
等使ってみたのですが、うまくいきません。
教えていただければ幸いです。
 

回答
投稿日時: 22/08/08 06:07:50
投稿者: WinArrow
投稿者のウェブサイトに移動

指定した条件のデータ(行)が複数件存在したら、どうするのですか?

回答
投稿日時: 22/08/08 07:06:41
投稿者: んなっと

Sheet1
 
  A   B   C   D   E
1 No  名前 金額A 金額B 日付
2  1 Aさん  100  9000  4/1
3  2 Bさん  200  8000  4/1
4  3 Cさん  300  7000  4/1
5  4 Dさん  100  6000  4/1
6  1 Aさん  500  1000  5/1
7  2 Bさん  900  2000  5/1
 
Sheet2
 
  A   B   C   D
1 No  名前 日付 金額A
2  1 Aさん  5/1  500
 
該当するデータが必ず一つだけであれば...
 
D2
=IF(B2="","",SUMIFS(Sheet1!C$2:C$100,Sheet1!$B$2:$B$100,$B2,Sheet1!$E$2:$E$100,$C2))
とか
=IF(B2="","",FILTER(Sheet1!C$2:C$100,(Sheet1!$B$2:$B$100=$B2)*(Sheet1!$E$2:$E$100=$C2),""))

回答
投稿日時: 22/08/08 22:19:09
投稿者: Mike

Sheet1             名前の管理
 A B  C  D  E      名前 参照範囲     範囲
1 No 名 額A 額B 日付     No  =Sheet1!$A$2:$A$7 ブック
2 1 A 100 9000 4/1     額A =Sheet1!$C$2:$C$7 ブック
3 2 B 200 8000 4/1     額B =Sheet1!$D$2:$D$7 ブック
4 3 C 300 7000 4/1     日付 =Sheet1!$E$2:$E$7 ブック
5 4 D 100 6000 4/1     名  =Sheet1!$B$2:$B$7 ブック
6 1 A 500 1000 5/1
7 2 B 900 2000 5/1
 
 
Sheet2
 A B  C  D
1 No 名 日付 額A
2 1 A 5/1 500
3 2 B 5/1 900
 
Sheet2!D2: =SUMIFS(額A,No,A2,日付,C2)
______または
______=SUMPRODUCT((No=A2)*(名=B2)*(日付=C2)*額A)

投稿日時: 22/08/08 23:23:14
投稿者: 55taru

皆さま、ご回答ありがとうございました。
指定した条件のデータ(行)は一つしか存在しないデータベースになっております。
言葉足らずで失礼いたしました。
 
皆さまの回答でうまく抽出することができました。
SUMIFS、FILTER等については意識して使っていなかった関数でした。今後忘れない関数となると思います。
大変勉強になりました、ありがとうございます、解決とさせていただきます。