Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 10 Pro : Excel 2016)
SUMIFS関数で「今月分」のみを合計したい
投稿日時: 21/04/30 12:49:09
投稿者: かうきのおやじ

購入日・氏名・購入金額などが縦に記録された表があります。
 
その中から「今月に買ったAさんの合計金額」が知りたいのです。
 
条件が、購入月と氏名の2つになるので「SUMIFS関数」を使うのが良いと考えます。
 
氏名の中からAさんのみを取り出すことは出来るのですが、購入日の中から「今月」に合致するものだけを取り出す方法で困っています。
 
私が作った式は次のようになります。
 
      合計対象範囲,条件範囲1,条件1,条件範囲2,条件2
 
 =SUMIFS( 購入金額の列, 氏名の列, 氏名, 購入日の列, MONTH(TODAY()) )
 
条件2の今月分の指定で戻り値は”可変”となっています。
 
作業セルを用意して「=MONTH(TODAY())」を求めた場合は正しく”4”となっているのですが、そのセルを条件2に入れると式の答えはゼロになってしまいます。
 
購入日の中から「今月」に該当するものだけを抽出する方法をご存知でしょうか?
 
あるいは、そもそもSUMIFS関数では無理なのでしょうか?

回答
投稿日時: 21/04/30 15:02:31
投稿者: WinArrow
投稿者のウェブサイトに移動

参考数式
 
=SUMIFS(C:C,A:A,">=2021/04/1",A:A,"<=2021/4/30",B:B,"A")
 
赤字部分が「今月」:範囲指定で

投稿日時: 21/04/30 16:56:38
投稿者: かうきのおやじ

WinArrow さんの引用:
参考数式
 
=SUMIFS(C:C,A:A,">=2021/04/1",A:A,"<=2021/4/30",B:B,"A")
 
赤字部分が「今月」:範囲指定で

__________________________________
赤字の部分は文字列で日付を指定する以外に方法はないのでしょうか?
 
この場合、月が替わるたびに式を修正する必要が出てきます。
 
試しに 2021/04/1 の部分の代わりに 4/1 と入力したセルを指定したら
合計はゼロになりました。ダブルクォーテーション””を取ってみたら「式に誤りがある」とエラーになってしまいました。
 
 
 
 

回答
投稿日時: 21/04/30 17:23:50
投稿者: WinArrow
投稿者のウェブサイトに移動

「以上」と「以下」を省略していませんか?
 
固定セルを参照する場合
=SUMIFS(B:B,A:A,">="&$D$1,A:A,"<="&$E$1)
 
セルD1の数式
=C1-DAY(C1)+1
 
セルE1の数式
=EOMONTH(C1,0)
 
 
セルC1の数式
=TODAY()
または、手入力(対象の月内の任意の日付)
 

回答
投稿日時: 21/04/30 17:26:51
投稿者: WinArrow
投稿者のウェブサイトに移動

セルD1の数式は、
↓の方が統一できるかも
=EOMONTH(C1,-1)+1

投稿日時: 21/04/30 18:24:11
投稿者: かうきのおやじ

ありがとうございます。
完璧にできました。
 
文字列とセル番地を&で繋ぐのを忘れておりました。
INDIRECTとか無駄な方法を試していました。
 
また、よろしくお願いします。 Very Happy