Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 10 Pro : Excel 2016)
複数条件のデータ個数を求める方法について
投稿日時: 21/04/23 18:23:48
投稿者: torao

 
お世話になっております。
シート内にあるリストから
 A列にある条件に該当する商品名から
 B列に値があれば
 その件数を求めたいと考えております。
 
 A列:商品名
 B列:値 ※空欄もある
 
 A列 B列
 あ 10 
 か
 い 10
 き 20
 う 10
 く
 え 10
 け 20
 お 10
 こ 20
 
(現在使用している式)
式=SUM(SUMIFS(リスト!B2:B100,リスト!A2:A100,{"あ","い","う","え","お"}))
合計値・・・50
 
(質問)
分からないことは
上記の条件で、B列の合計値ではなく「件数」を求める。
件数・・・5
 
現在使用している式をどのように変更すれば
 件数が求められるのか分からず質問させていただきました。
 皆様、アドバイスのほどよろしくお願いいたします。

回答
投稿日時: 21/04/23 19:21:01
投稿者: んなっと

B列に ="" [長さゼロの文字列]があるとだめ
=SUM(COUNTIFS(A2:A100,{"あ","い","う","え","お"},B2:B100,"<>"))
 
B列に負の数があるとだめ
=SUM(COUNTIFS(A2:A100,{"あ","い","う","え","お"},B2:B100,">=0"))
 
長い
=SUM(COUNTIFS(A2:A100,{"あ","い","う","え","お"},B2:B100,">="&MIN(B2:B100)))
 
わかりにくい
=SUM(COUNTIFS(A2:A100,{"あ","い","う","え","お"},B2:B100,">-9E15"))
 
意味不明
=COUNT(INDEX(0/MATCH(A2:A100,{"あ","い","う","え","お"},0)/(B2:B100<>""),))

回答
投稿日時: 21/04/23 19:23:16
投稿者: んなっと

リスト! 付け忘れました。

投稿日時: 21/04/23 20:02:04
投稿者: torao

 んなっと さん
 
いくつものパターンをアップしていただき感謝致します。
関数は奥が深く中々です。
 
今後ともご指導お願いいたします。