PowerPoint (一般・VBA)

PowerPoint 一般・VBAに関する話題を扱うフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(指定なし : 指定なし)
Re:「マクロにショートカットキーを付けるには」のmayuwankoさんへ
投稿日時: 21/02/17 11:47:20
投稿者: んなっと

例えば FontRed というマクロが使える状態で、
キーボードショートカットを CTRL+ALT+R に設定したい場合。
 
Sub VBS_Shortcut()
  'C:\ユーザー\(ユーザー名)\AppData\Roaming\Microsoft\Windows\スタート メニュー フォルダに
  'FontRed.vbs と FontRedへのリンク の2つのファイルを作成します。
  'キーボードショートカットはCTRL+ALT+Rです。
  '機能が不要になったら上記2つのファイルを削除して再起動してください。
  VBSShort "FontRed", "CTRL+ALT+R"
End Sub
Sub VBSShort(myName As String, HKey As String)
  Dim FSO, WSHShell
  Dim myPath As String
  Set WSHShell = CreateObject("WScript.Shell")
  myPath = WSHShell.SpecialFolders("StartMenu")
  Set FSO = CreateObject("Scripting.FileSystemObject")
  With FSO.CreateTextFile(myPath & "\" & myName & ".vbs", True)
    .WriteLine "Dim PPT"
    .WriteLine "On Error Resume Next"
    .WriteLine "Set PPT = GetObject(, ""PowerPoint.Application"")"
    .WriteLine "WScript.Sleep 10"
    .WriteLine "PPT.Run """ & myName & """"
    .WriteLine "PPT.Activate"
    .WriteLine "Set PPT = Nothing"
    .Close
  End With
  With WSHShell.CreateShortcut(myPath & "\" & myName & "へのリンク.lnk")
    .TargetPath = myPath & "\" & myName & ".vbs"
    .WorkingDirectory = myPath
    .WindowStyle = 0
    .HotKey = HKey
    .Save
  End With
End Sub
 
"FontRed", "CTRL+ALT+R" を
"MacroPre.pptm!ClassStart", "CTRL+SHIFT+F10" などに変更。

投稿日時: 21/02/17 11:47:48
投稿者: んなっと

豚汁。