スキルアップ・問題解決なら、モーグにおまかせ！

セルに
0110　と入力したら　21/01/10(日)
1001　　　　21/10/01(金)
200131 　　　20/01/31(金)
と、いうようにしたいと考えています。
 
最初の入力された文字列を取得を取得するところでつまずいてしまいました。
Ｂ列への入力を考えています。
Ｂ列の書式設定は"yy/mm/dd(aaa)"としています。
 
次のようにコーディングを始めましたが、
４文字の入力か否かのところで行き詰まってしまいました。
「0110」と入力すると「110」
となってしまいます。
 
ここができたら、
４文字の時は頭に「21]を付ける
その数値の妥当性を判断する
という様な処理を行っていきたいと思っています。
入力文字の４文字判定ができなければ先へ進めません。
 
どうかよろしくお願いいたします。
 
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim colName, colNo
    Dim re As New RegExp
    Dim inputDat As Variant
    colNo = Selection.Column
    re.Pattern = "\d{4}"
    re.Global = True
    colName = ColAddr(colNo)
    Target.NumberFormatLocal = "@" '"文字列"
    inputDat = Target.Text
    MsgBox ("入力しました inputDat=" & inputDat & " colName=" & colName)
    If colName = "B" Then
        If re.test(inputDat) Then
            MsgBox "数字４文字"
        Else
            MsgBox "数字４文字でない"
        End If
    End If
    Target.NumberFormatLocal = "yy/mm/dd(aaa)" '"ユーザー定義書式"
End Sub
 

横着しない方が、操作上も、以後のメンテナンスでも
 よっぽど簡単だと思いいますが・・・・
  
 >「0110」と入力すると「110」
これは当たり前です。
 先頭に「0」をプログラムで認識（取得）するためには、表示形式を「文字列」に設定するしかありません。
 
Ａ列セルに
1/10
入力すると
2021/01/10と解釈されます。
 
どうしてもというのでしたら
Ａ列セルを文字列に設定することです。

> Target.NumberFormatLocal = "@" '"文字列"
 
このコードは、入力する前でないと無意味
従って、不要です。

表示形式をセル単位に設定していますが、
列で設定したほうがよいです。
処理速度、ファイル容量的にもメリットがあります。
 
なぜ、」ＶＢＡで対応しようとしているかわかりませんが、
予めＡ列を文字列に設定します。
Ｂ列に表示形式：ユーザー定義　yy/mm/dd(aaa)に設定しておきます。
 
Ｂ列セルの数式
=IF(LEN(A2)=4,DATE(2021,LEFT(A2,2),RIGHT(A2,2)),IF(LEN(A2)=6,DATE("20"&LEFT(A2,2),MID(A2,3,2),RIGHT(A2,2)),"エラー"))
 
で対応できます。
 

WinArrow さんの引用:

 >「0110」と入力すると「110」
これは当たり前です。
 先頭に「0」をプログラムで認識（取得）するためには、表示形式を「文字列」に設定するしかありません。

今更・・・・
 
コードを眺めていたら
Ｂ列セルに、セットするところが見当たらない・・・？？
見落としていたらごめんなさい
 
もし、
21/01/10(日)
という値をセットしていたら（セットするつもり）
表示形式で yy/mm/dd(aaa) をセットしているが無意味です。

既に指摘されていますが、
"0102"と入力すると、そのセルが文字列書式でなければ、
Excel君が気を利かせて、 102と解釈してくれるのですね。
こういうのは「小さな親切、大きなお世話」と感じる時もありますね。
 
別手法ですが、ダブルクリックイベントプロシージャとInputboxメソッドを使うと、
上記の話は避けることができますね。
 

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim s As String
    Dim d As Date
    
    Cancel = True
    If Target.Column <> 2 Then Exit Sub

    s = Application.InputBox("4桁の数値を入力", Type:=2)
    If Len(s) <> 4 Or Not IsNumeric(s) Then
        MsgBox "4桁の数字を入れてください"
        Exit Sub
    End If
    
    d = DateSerial(Year(Date), Val(Left(s, 2)), Val(Right(s, 2)))
    Application.EnableEvents = False
    Target.NumberFormatLocal = "yy/mm/dd(aaa)"    '"ユーザー定義書式"
    Target.Value = d
    Application.EnableEvents = True
End Sub

どうしてもChangeイベントプロシージャだというなら、こうですか。
事前にB列を文字列書式にしておいてください。
また、複数のセルを同時に変更することは考慮外です。（コピーペイストで更新するなど）
 

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim colNo As Long
    Dim re As RegExp
    Dim s As String
    
    colNo = Target.Column
    If colNo <> 2 Then Exit Sub

    Set re = New RegExp
    re.Pattern = "\d{4}"
    re.Global = True
    
    s = Target.Text
    If re.test(s) Then
        Target.NumberFormatLocal = "G/標準"
        Application.EnableEvents = False
        Target.Value = DateSerial(Year(Date), Val(Left(s, 2)), Val(Right(s, 2)))
        Application.EnableEvents = True
        Target.NumberFormatLocal = "yy/mm/dd(aaa)"
    Else
        MsgBox "数字４文字ではない"
        Application.EnableEvents = False
        Target.ClearContents
        Application.EnableEvents = True
    End If
End Sub

WinArrow さんの引用:

Ｂ列セルに、セットするところが見当たらない・・・？？
もし、
21/01/10(日)
という値をセットしていたら（セットするつもり）
表示形式で yy/mm/dd(aaa) をセットしているが無意味です。

WinArrow さんの引用:

Ｂ列セルに、セットするところが見当たらない・・・？？
もし、
21/01/10(日)
という値をセットしていたら（セットするつもり）
表示形式で yy/mm/dd(aaa) をセットしているが無意味です。

>1001　　　　21/10/01(金)
>200131 　　　20/01/31(金)
 
のような入力が前提なら、６文字判定でもいいんじゃないですか？

simple さんの引用:
どうしてもChangeイベントプロシージャだというなら、こうですか。

チオチモリン さんの引用:
>1001　　　　21/10/01(金)
>200131 　　　20/01/31(金)
 
のような入力が前提なら、６文字判定でもいいんじゃないですか？

↓のような意味なんですけど。　意味違いました？
 
Private Sub Worksheet_Change(ByVal Target As Range)
    MsgBox IIf(Len(Target.Value) = 6, "数字４文字でない", "数字４文字")
End Sub

6桁の話を読み飛ばしていました。失礼。
 
基本的なことを理解されたほうがいいですよ。
yy/mm/dd(aaa)の書式設定されたセルに入力すべきは、
Date型の数値です。実体は整数です。
それを“0102"といった文字列を入力するのはNGです。
 
一旦Inputboxなどで受けてDate型に変更したうえで
当該セルに入れるのが自然でしょう。
または別の入力セルを使い、当該セルには、そのセルを参照し、
文字列をDate型に変換する数式を入れておくかです。

すみません
Ａ列に入力して、Ｂ列に転送しえいるものと勘違いしていました。
 
Ｂ列セルに入力したデータを変換したい
ということですね
 
参考コードを紹介します。
予めＢ列セルは、文字列に設定しておきます。
Ｂ列セルを一旦文字列変数に入れて、桁数判定後、値をセットする前に表示形式をセットします。
 

Private Sub Worksheet_Change(ByVal Target As Range)
Dim DAtA As String

    If IsDate(Target.Value) Then Exit Sub
    DAtA = Target.Value
    Select Case Len(DAtA)
        Case 4
            Target.NumberFormatLocal = "yy/mm/dd(aaa)"
            Target.Value = DateValue("2021/" & Left(DAtA, 2) & "/" & Right(DAtA, 2))
        Case 6
            Target.NumberFormatLocal = "yy/mm/dd(aaa)"
            Target.Value = DateValue("20" & Left(DAtA, 2) & "/" & Mid(DAtA, 3, 2) & "/" & Right(DAtA, 2))
        Case Else
            MsgBox "桁数が不正です"
    End Select

End Sub

>Ｂ列のセルに入力された値−Target
>と、いうことでコーディングしたつもりですが・・・
 
でも、値が変更されていない状態で、表示形式だけ変更したら、どうなるか検証してみましたか？
例えば、1110　とか201112 の状態で yy/mm/dd(aaa) に変更してみてください。

追伸
 
あたしの参考コードは、かなり手抜きがあるので、
例えば、「Ｂ列セル以外はスキップするとか」必要な部分は追加してくださいね。

>yy/mm/dd(aaa)の書式設定されたセルに入力
そうだったんですか
 
初レスで
>0110」と入力すると「110」となってしまいます。
とあったので
>yy/mm/dd(aaa)の書式設定されたセルに入力
とは考えていませんでした。
その後の展開で話は進んでいたんですね。
失礼しました。

多くの方から、多くのことを教えていただき感謝です。
教えていただいたコードで動作を確認しています。
 
simpleさんの言われるように
＞"0102"と入力すると、そのセルが文字列書式でなければ、
＞Excel君が気を利かせて、 102と解釈してくれるのですね。
＞こういうのは「小さな親切、大きなお世話」と感じる時もありますね。
と、つくづく思います。
エクセルが、便利ツールとして提供されてきたから仕方ないのかな。
表面的な処理が重要視されすぎてしまう。

横から失礼します。
「110」を「0110」で処理するのは駄目でしょうか。
3桁入力と4桁入力を区別できず、「0110」入力も「110」入力もOKになってしまいますが。
エラー処理や表示処理を省いて、しかも少し雑ですが、書いてみました。
参考になれば。
 

Private Sub Worksheet_Change(ByVal Target As Range)
    
    Dim re As Object
    Dim strDate As String
    
    Set re = CreateObject("VBScript.RegExp")
    re.Pattern = "^\d+$"
    re.Global = True
    
    If re.Test(Target.Value2) = True Then
       Target.NumberFormatLocal = "yy/mm/dd(aaa)" '"ユーザー定義書式"
       If CLng(Target.Value2) >= 10000 Then
          'yymmdd形式と見做す
          strDate = CStr(Target.Value2 + 20000000)
       Else
          'mmdd形式と見做す
          strDate = CStr(Target.Value2 + 20210000)
       End If
       Application.EnableEvents = False
       Target.Value = DateValue(Left$(strDate, 4) & "/" & Mid$(strDate, 5, 2) & "/" & Right$(strDate, 2))
       Application.EnableEvents = True
    End If

End Sub

話は違うが
↓の件で
https://www.moug.net/faq/viewtopic.php?t=80151
 
 
0!/00!/00
という表示形式で解決した
ということでよろしいのでしょうか？
 
これは単純に見た目だけのことで、データとして、日付になっているわけではないので、
計算には使えません。

>Ｂ列の書式設定は"yy/mm/dd(aaa)"としています。
この状態で
>「0110」と入力すると「110」
>となってしまいます。
という説明には、違和感があります。
どのような方法で確認したのでしょうか？
 
状況を正確に伝えていただきたいですね・・・・
 そうでないと、空回りしたり、質問者の意図と異なる回答が付くことになります。
 
 
表示形式は、見た目を設定するもので、「値」には影響は与えません。
ですから、予め「yy/mm/dd(aaa)という表示形式が設定してあるセルに
「110」を入力した時
「値」はもちろん「110」です。
コード実行の途中で表示形式を「@」に変更していますが、「値」が変わるわけではないです。
 

ありがとうございました。
これです。
このような処理ができないものかと思っていました。
 

K.Hiwasa さんの引用:

    If re.Test(Target.Value2) = True Then

WinArrow さんの引用:
https://www.moug.net/faq/viewtopic.php?t=80151
0!/00!/00
という表示形式で解決した
ということでよろしいのでしょうか？
これは単純に見た目だけのことで、データとして、日付になっているわけではないので、
計算には使えません。

 
参考資料
セルの「Value」「Text」「Value2」プロパティの違いを理解しましょう。
その上で、どのようにセルに入力すればよいか、および、その使い方を考える参考にしてください。
  
Sub test()
Dim myCell As Range
 
    Set myCell = Range("A1")
    Debug.Print "�@表示形式：標準、201120入力"
    With myCell
        .NumberFormatLocal = "G/標準"
        .Value = "201120"
        .NumberFormatLocal = "0!/00!/00"
        GoSub Print_Prc
    End With
     
    Set myCell = myCell.Offset(1)
    Debug.Print "�A表示形式：標準、2020/11/20入力"
    With myCell
        .NumberFormatLocal = "G/標準"
        .Value = "2020/11/20"
        .NumberFormatLocal = "yy/mm/dd(aaa)"
        GoSub Print_Prc
    End With
     
    Set myCell = myCell.Offset(1)
    Debug.Print "�B表示形式：文字列、201120入力"
    With myCell
        .NumberFormatLocal = "@"
        .Value = "201120"
        .NumberFormatLocal = "yy/mm/dd(aaa)"
        GoSub Print_Prc
    End With
     
    Set myCell = myCell.Offset(1)
    Debug.Print "�C表示形式：文字列、201120入力"
    With myCell
        .NumberFormatLocal = "@"
        .Value = "201120"
        .NumberFormatLocal = "0!/00!/00"
        GoSub Print_Prc
    End With
     
    Set myCell = myCell.Offset(1)
    Debug.Print "�D表示形式：標準､0120入力 """
    With myCell
        .NumberFormatLocal = "G/標準"
        .Value = "0120"
        .NumberFormatLocal = "yy/mm/dd(aaa)"
        GoSub Print_Prc
    End With
     
    Set myCell = myCell.Offset(1)
    Debug.Print "�E表示形式：文字列､0120入力 """
    With myCell
        .NumberFormatLocal = "@"
        .Value = "0120"
        .NumberFormatLocal = "yy/mm/dd(aaa)"
        GoSub Print_Prc
    End With
    Exit Sub
Print_Prc:
    With myCell
        Debug.Print .Address(0, 0) & ":Value = " & .Value
        Debug.Print .Address(0, 0) & ":Text = " & .Text
        Debug.Print .Address(0, 0) & ":Value2 = " & .Value2
    End With
    Return
         
End Sub

WinArrow さんの引用:
参考資料

面白テスト
 

Sub test()
Dim DT

    With Range("A1")
        .NumberFormatLocal = "0!/00!/00"
        .Value = "0100"
        Select Case Len(.Value)
            Case 3, 4
                DT = Split(.Text, "/")
                .NumberFormatLocal = "yy/mm/dd(aaa)"
                .Value = DateSerial(2021, DT(1), DT(2))
            Case 6
                DT = Split(.Text, "/")
                .NumberFormatLocal = "yy/mm/dd(aaa)"
                .Value = DateSerial(DT(0) + 2000, DT(1), DT(2))
            Case Else
                MsgBox "桁数エラー"
        End Select
    End With
End Sub

更に、貴重なコードの提示、ありがとうございます。
何故か、無限ループに入ってしまいます。
じっくりと調べて見ます。
当初の目的はおかげで達成できました。
一端、閉じさせていただきます。
みなさん、本当にありがとうございました。