スキルアップ・問題解決なら、モーグにおまかせ！

選択肢がなかったので Excel 2016 としてますが Excel 2019 です
 
点訳のお手伝いをさせていただいておりますが、たとえば
セルの中に『１枚』の文字があった場合、次のセルに『＃1まい』と点訳するための
文字列に変換しています（基本はひら仮名を使用）
※『＃』は『点字線付』フォントでは右図のように　　　　　　　−●
　６点の内 ３､４､５､６の点で逆Ｌ字型となり　　　　　　　　　−●
　その後の点字は数字ですよという『数符』を表す　　　　　　　●●
 
あまり一般的ではないため『ゴシック』の中に１〜２文字『明朝』が混じっている
みたいに考えていただければ良いかと思います　
 
この『数符』を目立つように赤に色付けするため下記のマクロを作成しました
 
上記の『＃１まい』の場合はＯＫなんですが　　　※『＃』は『点字線付』フォント
例えば『＃１おく　＃５０００まん』のように　　※『＃』は『点字線付』フォント
一つのセルに２個あった場合に最初の『＃（点字線付フォント）』が
『＃（ＭＳゴシックフォント）』に戻ってしまいます
 
※ＥＸＣＥＬ全体は『ＭＳゴシック』フォントが標準で
　『数符』のみ『点字線付』フォントに変更しています
 
『myRng』セルの中を１文字ずつ順番に調べてフォント名が『点字線付』だったら
赤色に変更するというマクロです
---------------------------------------------------------
  For i = 1 To Len(myRng)
    If myRng.Characters(i, 1).Font.Name = "点字線付" Then
      myRng.Characters(i, 1).Font.ColorIndex = 3
    End If
  Next i
---------------------------------------------------------
 
１文字がＯＫで２文字目がダメな理由がわかりません
正月早々恐縮ですがご教示いただければと思います
 
説明がわかりにくいかと思いますが、よろしくお願いいたします

参考オード
 
Dim myRNG As Range
Dim i As Long
    Set myRNG = Range("A1")
    With myRNG
        For i = 1 To Len(.Value)
            If .Characters(Start:=i, Length:=1).Font.Name = "○○○" Then
                .Characters(Start:=i, Length:=1).Font.ColorIndex = 3
            End If
        Next
    End With

当方もExcel2019ですが、再現しませんねえ。
（一つのセルの中で、フォントを二種類設定した箇所を複数作り、
特定フォントのみ赤字にすると、その部分だけ赤くなりますよ。）
 
念のための確認ですが、
(1)コードを省略せずに提示してもらえますか？
   Sub　から　変数宣言とかも省略せずに　End Subまで記載してもらえますか？
   なにか記載を省略している作業は無いですか？
(2)
>セルの中に『１枚』の文字があった場合、次のセルに『＃1まい』と点訳するための
>文字列に変換しています（基本はひら仮名を使用）
とのことですが、#以外はどんなフォントなんですか？
#以外は点字ではない普通のフォントなんですか？
 
まったく別のブックで、再度トライしてみては々でしょうか。
なんらかの思い違いとか混入していないでしょうか。
ちょっと普通では想定しにくいことですよね。
（だから質問なさったのでしょうけど。）
 
# WinArrowさんのコードは、質問者さんのコードとほぼ同じような気がしますが・・・。

正月の休みにもかかわらず早速回答いただきましてありがとうございます
 
WinArrowさんの回答にてテストいたしましたが結果は同じでした
 
simpleさんの回答に対して下記を追加します
 
（2）#以外は点字ではない普通のフォントなんですか？
セルには『＃１まい』と『ＭＳゴシック』フォントで入力後『＃』を選択し
『点字線付』フォントに変換しています
 
（1）コードを省略せずに提示してもらえますか？
コードは下記の通りです
-------------------------------
Sub mojiiro()
 
Dim myRng As Range
Dim i As Integer
 
Worksheets(1).UsedRange.Select
For Each myRng In Selection
 
'----異なるフォントが混在するセルのみ処理する
'----セルの中にフォントが混在していると『Null』を返す
  If (IsNull(myRng.Font.Name) = True) Then
 
'----セルの文字列を1文字ずつ順番に調べる
  For i = 1 To Len(myRng)
    If myRng.Characters(i, 1).Font.Name = "点字線付" Then
      myRng.Characters(i, 1).Font.ColorIndex = 3
    End If
  Next i
  End If
Next myRng
 
End Sub
---------------------------------
出来ればどこが悪いのかもお教えいただけると助かります
 
以上、よろしくお願いいたします

このコードを実行すると、
フォントが変わってしまう
ということでしょうか？
 
私の環境には、『点字線付』フォントがありませんので、
同じ条件では、再現テストはできません。
 
フォント名をイミディトウィンドウに表示するなどを追加して
ステップ実行してみましょう。
 

すみません
さっきのに追記しておけばよかったのですが・・・
 
『＃１おく　＃５０００まん』をステップ実行すると
最初の『＃』は『点字線付』フォントのまま赤色になります
これは意図したとおりです
そのあとは　１、お、く、（スペース）、までは黒色のまま進みます
ここまでは意図したとおりに進みます
次のステップで
２度目の『＃』が『点字線付』フォントのまま赤色になると同時に
最初の『＃』が赤色のまま『ＭＳゴシック』フォントに変わります
これがなぜなのかわかりません
 
以上、よろしくお願いいたします

引用:
セルには『＃１まい』と『ＭＳゴシック』フォントで入力後『＃』を選択し
『点字線付』フォントに変換しています

そうですよね
『点字線付』フォントなんて使う人は少ないですよね
 
例えば『ＭＳゴシック』の中に数文字『HGP創英角ﾎﾟｯﾌﾟ体』を入れる
とかでも結果的に同じようになるのではないかと思いますが
 
なんて、お願いしている身で申し訳ありません

myubu さんの引用:
すみません
さっきのに追記しておけばよかったのですが・・・
 
『＃１おく　＃５０００まん』をステップ実行すると
最初の『＃』は『点字線付』フォントのまま赤色になります
これは意図したとおりです
そのあとは　１、お、く、（スペース）、までは黒色のまま進みます
ここまでは意図したとおりに進みます
次のステップで
２度目の『＃』が『点字線付』フォントのまま赤色になると同時に
最初の『＃』が赤色のまま『ＭＳゴシック』フォントに変わります
これがなぜなのかわかりません
 
以上、よろしくお願いいたします

回答ありがとうございました。
 
Excel2010,2019の両方で、検証してみましたが、再現できませんでした。
ただし、こちらの検証範囲が狭いのかも知れませんので、
そうした事象が発生しないと断言するつもりもありません。
フォントの関係かも知れませんね。
お力になれませんでした。
 
参考までに検証コードを挙げておきます。

Sub test()
    Call defaultfont([A1])
    Call changefontColor([A1])
    Call changefontColor([A1])
End Sub

Function defaultfont(r As Range)
    With r
        .Value = "aaaaabbbccc"
        .Font.ColorIndex = xlAutomatic
        .Font.Name = "ＭＳ Ｐ明朝"
        .Characters(Start:=1, Length:=1).Font.Name = "ＭＳ Ｐゴシック"
        .Characters(Start:=6, Length:=1).Font.Name = "ＭＳ Ｐゴシック"
        .Characters(Start:=9, Length:=1).Font.Name = "ＭＳ Ｐゴシック"
    End With
End Function
Sub changefontColor(r As Range)
    Dim i&
    If IsNull(r.Font.Name) Then
        For i = 1 To Len(r)
            With r.Characters(i, 1).Font
                Debug.Print i; .Name; .ColorIndex
                If .Name = "ＭＳ Ｐゴシック" Then
                    .ColorIndex = 3
                End If
            End With
        Next i
        Debug.Print "----------------"
    End If
End Sub

WinArrow さんの引用:

若し、手操作でしたら、その時に赤字に変更すればよいのではの？
ＶＢＡで操作しているのでしたら、対象文字列を指定しているんだから、一緒に色も変更すれば？

墨点字フォントを入れて、A1セルに『＃１まい』、A2セルに『＃１おく　＃５０００まん』と入力して、＃を点字線付に変更して実行したところ、再現しました。
他のフォントでも、再現しました。
 
２回目の色設定の際に、1回目の色変更箇所のフォントがMSゴシックになります。
しかも1回目の色変更箇所が1文字目の場合のみのようです。
また、マクロでフォントを設定した場合は、大丈夫なようです。
（2回目の実行では、追加部分なしでも戻されません。）
なぜこの現象が起こるかはわかりませんが、上記を踏まえて対処しました。
 

Sub mojiiro()
 
Dim myRng As Range
Dim i As Integer

Worksheets(1).UsedRange.Select
For Each myRng In Selection
 
'----異なるフォントが混在するセルのみ処理する
'----セルの中にフォントが混在していると『Null』を返す
  If (IsNull(myRng.Font.Name) = True) Then
 
'----セルの文字列を1文字ずつ順番に調べる
     For i = 1 To Len(myRng)
        If myRng.Characters(i, 1).Font.Name = "点字線付" Then
           myRng.Characters(i, 1).Font.ColorIndex = 3
'----1文字目の場合、フォントをマクロで再設定
           If i = 1 Then
              myRng.Characters(i, 1).Font.Name = "点字線付"
           End If
        End If
     Next i
  End If
Next myRng
 
End Sub

WinArrowさん、simpleさん、K.Hiwasaさん
皆さん正月早々からありがとうございました
 
K.Hiwasaさんの『ＶＢＡによる再設定』でうまくいきました
 
残念ながら原因については不明（おそらく、バグ？）との事
当然、私にわかるはずもないと納得しました
 
皆さんお忙しい中、本当にありがとうございました