スキルアップ・問題解決なら、モーグにおまかせ！

教えてください。VBA初心者です。
 
フォーマットが同じ任意の数のシートの特定の行をコピーしてその行だけ新しいシートに順番に張り付けていきたいです。
例えば、個人ごとに月ごとの売り上げを記録しているシートがあるとして
一番最後の行Rows(13)にSUM関数でこれまでの売り上げを計算しているとして、
そのSUM関数が入っている13行目だけをコピーしていきたいです。
値だけわかればいいので、関数はコピーしなくてもいいです。
 
見出しみたいなものは、13行目に含まれているので必要なく、
ただ既存のすべてのシートの13行目を新しいシートに上から順番にはりつけていくイメージです。
 
年末のお忙しい時期にすみません、
よろしくお願いいたします。

オートフィルタは、知っていますか？
オートフィルタで、合計行だけ表示することができれば、
見えている行だけ、別シートに複写可能です。
 
まず、手操作で実行を確かめて、意図したことができたのでしたら、
その操作をマクロの記録でコードを作成しましょう。

WinArrow様
返信ありがとうございます。
オートフィルタは知っています。
すみません、ここに書くのに分かりやすい例えを考えて書いたつもりでしたが例えが悪かったです。
実際は、コピーしたい行が欄外というか、本体の表とくっついていなくて、セル毎にいろいろな関数が含まれています。
なんとなく、for erch〜nextとcopyで書くんだろうなというのはわかるんですが、そこまでで思考がとまってます。
それとも「見えてる行だけ複写する」ということなら、その行以外は消去して残りを積み上げていく方がいいんでしょうか。そうなるとコードの想像がつきません。

あべの さんの引用:

実際は、コピーしたい行が欄外というか、本体の表とくっついていなくて、セル毎にいろいろな関数が含まれています。

あべの さんの引用:

なんとなく、for erch〜nextとcopyで書くんだろうなというのはわかるんですが、そこまでで思考がとまってます。
それとも「見えてる行だけ複写する」ということなら、その行以外は消去して残りを積み上げていく方がいいんでしょうか。そうなるとコードの想像がつきません。

>ただ既存のすべてのシートの13行目を新しいシートに上から順番にはりつけていくイメージです。
 
この条件だけで参考コードを提示します。
 

Sub 各シートの13行目だけを新規シートに複写する()
Dim NewSheet As Worksheet, scnt As Long

    With ActiveWorkbook
        If .Sheets(.Sheets.Count).Name <> "NEW" Then
            .Sheets.Add after:=.Sheets(.Sheets.Count)
            Set NewSheet = ActiveSheet
            NewSheet.Name = "NEW"
        Else
            Set NewSheet = .Sheets(.Sheets.Count)
        End If
        NewSheet.Activate
        For scnt = 1 To .Sheets.Count - 1
            If .Sheets(scnt).Name = "NEW" Then Exit For
            .Sheets(scnt).Rows(13).Copy
            NewSheet.Range("A" & NewSheet.Rows.Count).End(xlUp).Offset(1).EntireRow.PasteSpecial (xlPasteValues)
        Next
    End With
End Sub

>任意の数のシートの特定の行をコピーしてその行だけ新しいシートに順番に張り付けていきたい
 

Sub test()
    Dim ws As Worksheet
    Dim wsResult As Worksheet
    Dim ixRow As Long
    
　　'新しいシートの挿入
    With Worksheets
        Set wsResult = .Add(after:=.Item(.Count))
    End With
　　'貼り付け行番号初期値
    ixRow = 2
    
    '各シートの繰り返し
    For Each ws In Worksheets
        '新しいシート以外なら
        If Not ws Is wsResult Then
            'コピー
            ws.Rows(3).Copy
            '値のみ貼り付け
            wsResult.Rows(ixRow).PasteSpecial xlPasteValues
            '次の貼り付け先の行番号
            ixRow = ixRow + 1
        End If
    Next
End Sub

お二方、ありがとうございます。
書き込みに気づくのが遅れ、お礼が遅くなり申し訳ありません。
 
また仕事の都合で教えて頂いたものを試すのが月曜以降になってしまいます。また結果を後日ご報告いたします。
ありがとうございました。