Excel (VBA)

Excel VBAに関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 10全般 : Excel 2010)
ユーザーフォームにセル番地の表示
投稿日時: 20/11/11 14:20:54
投稿者: abc_d

宜しくお願い致します。
 
アクティブなセル番地をユーザーフォームのラベルに
表示させて、セル選択を変えるたびに
ラベル表示が変わるということはできるのでしょうか。
 
ユーザー起動時に表示させるのはできたのですが…
 
Label1.Caption = ActiveCell.Address(False, False)
 
 
以上どうぞよろしくお願い致します。

回答
投稿日時: 20/11/11 14:38:58
投稿者: sk

引用:
アクティブなセル番地をユーザーフォームのラベルに
表示させて、セル選択を変えるたびに
ラベル表示が変わるということはできるのでしょうか。

(フォームモジュール)
------------------------------------------------------------
Option Explicit
 
Private WithEvents MyApp As Excel.Application
 
Private Sub UserForm_Initialize()
 
    Set MyApp = Application
    Call SetLabelCaption
 
End Sub
 
Private Sub UserForm_Terminate()
 
    Set MyApp = Nothing
 
End Sub
 
Private Sub MyApp_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
 
    Call SetLabelCaption
 
End Sub
 
Private Sub SetLabelCaption()
 
    Me.Label1.Caption = ActiveCell.Address(False, False)
 
End Sub
------------------------------------------------------------
 
あとはそのユーザーフォームをモードレスモードで開けばよいでしょう。

投稿日時: 20/11/11 15:04:04
投稿者: abc_d

sk様
 
お早いご対応ありがとうございました。
 
早速試してみました。
おかげさまで無事表示させることが出来ました。
 
ありがとうございました。