Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 10 Home : Excel 2016)
別表で集計
投稿日時: 20/07/20 12:32:48
投稿者: nob1122

会計簿を作りたいのですが、困っています。
    
(ア表)
  A B      
1 1 100
2 2 200
3 3 100
4 1 400
5 1 200
       
(イ表)ア表のA列に「1」と入力されているものを集計
  A      
1 100
2 400
3 200
       
イ表にどんな関数を組めばよいか悩んでいます。場合によっては、ア表に何らかの仕掛けを作ることも考えています。 単純にイ表に計算結果(合計など)を載せるのではなく、改めて、条件にあった(A列で1と入力されている)行を表示したいと思います。
    
よろしくお願いします。

回答
投稿日時: 20/07/20 12:53:40
投稿者: んなっと

作業列を使う方法がベストですが、データ数が少なければこんな方法も。
 
●Sheet1
 
  A  B
1 1 100
2 2 300
3 3 600
4 1 400
5 1 200
 
●Sheet2
 
   A
1 100
2 400
3 200
4   
 
A1
=IFERROR(INDEX(Sheet1!B:B,AGGREGATE(15,6,ROW($1:$200)/(Sheet1!$A$1:$A$200=1),ROW(A1))),"")
下方向・↓

投稿日時: 20/07/20 12:59:38
投稿者: nob1122

んなっと 様、早速の回答に感謝します。
 
もしできれば、作業列の方法も教えていただけますか?

回答
投稿日時: 20/07/20 14:14:46
投稿者: Suzu

引用:
場合によっては、ア表に何らかの仕掛けを作ることも考えています。

 
(ア表)
    A    B
1    F1    F2
2    1    100
3    2    200
4    3    100
5    1    400
6    1    200
 
の様に 先頭にフィールド名を入れて良いなら
 
 
フィルターを設定してしまえば?
 
 
更に、並び順を変えてよいなら
ピボットテーブルを利用しても良いと思います。

回答
投稿日時: 20/07/20 15:29:00
投稿者: Mike

Sheet1        Sheet2
 A B          A  B  C D
1 1 100        1  1  2  3 ←Sheet1のA列番号
2 2 200        2 100 200 100
3 3 100        3 400
4 1 400        4 200
5 1 200        5
 
Sheet2!A2: =IFERROR(INDEX(Sheet1!$B$1:$B$100,SMALL(IF(Sheet1!$A$1:$A$100=A$1,ROW(A$1:A$100)),ROW(A1))),"")
【御斷はり】上式は必ず配列數式として入力の事

回答
投稿日時: 20/07/20 16:01:03
投稿者: んなっと

●Sheet1
 
  A  B C
1 1 100 1
2 2 300 1
3 3 600 1
4 1 400 2
5 1 200 3
 
C1
=COUNTIF(A$1:A1,1)
下方向・↓
 
 
 
●Sheet2
 
   A
1 100
2 400
3 200
4   
 
A1
=IFERROR(INDEX(Sheet1!B:B,MATCH(ROW(A1),Sheet1!C:C,0)),"")
下方向・↓
 
 
 
※Sheet1の一番上に見出し行があれば、軽くなります。
 
   A   B C
1 No. 金額  
2  1  100 1
3  2  300 1
4  3  600 1
5  1  400 2
6  1  200 3
 
C2
=C1+(A2=1)
下方向・↓

投稿日時: 20/07/20 17:05:06
投稿者: nob1122

コメントいただいた皆様へ
 
大変、ありがとうございました。
 
皆様のおかげで、解決です。