Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 10 Home : Excel 2016)
HYPERLINK関数とMATCH関数について
投稿日時: 20/06/17 15:15:10
投稿者: 河童@TKO

お世話になります。
HYPERLINK関数とMATCH関数を組み合わせてリンクを作成したいと思っています。
 
タスク管理.xlsx に
「得意先リスト」と「タスク管理」というシートがあります。
 
「得意先リスト」シート
A列・・・得意先ID(数字)
B列・・・得意先名
 
「タスク管理」シート
B列・・・得意先ID
C列・・・タスクID
などがあります。
タスク管理は都度行が増えていきます。
 
やりたいことは、
「得意先リスト」シートのA列の値をクリックすると
「タスク管理」シートのB列を検索して最初にヒットしたセルにリンクを貼りたいです。
 
「得意先リスト」シートの「A4」セルには得意先ID「3」とする場合
=HYPERLINK("#タスク管理!B"&MATCH(A4,"#タスク管理!B:B",0),3)
循環参照のエラーが発生してしまいます。
 
検索範囲が別シートにあり、一致する値のセルにリンクを貼るには
どの様にすれば良いでしょうか?
お教えください。よろしくお願い致します。

回答
投稿日時: 20/06/17 17:31:37
投稿者: んなっと

●タスク管理
 
     B     C
1 得意先ID 得意先名
2     1    あ
3     2    い
4     3    う
5     4    え
6     5    お
 
●得意先リスト
 
※B列の得意先名を入力して、それを参照するなら...
 
     A     B
1 得意先ID 得意先名
2     5    お
3     1    あ
4     3    う
 
A2
=HYPERLINK("#タスク管理!B"&MATCH(B2,タスク管理!C:C,0),INDEX(タスク管理!B:B,MATCH(B2,タスク管理!C:C,0)))
下方向・↓
 
 
※A列の得意先IDを入力して、それを参照するなら
 
     A     B      C
1 得意先ID 得意先名 ↓クリック
2     5    お  ジャンプ
3     1    あ  ジャンプ
4     3    う  ジャンプ
 
B2
=VLOOKUP(A2,タスク管理!B:C,2,FALSE)
下方向・↓
C2
=HYPERLINK("#タスク管理!B"&MATCH(A2,タスク管理!B:B,0),"ジャンプ")
下方向・↓

投稿日時: 20/06/17 18:28:48
投稿者: 河童@TKO

んなっとさん、ありがとうございます。
 
C2
=HYPERLINK("#タスク管理!B"&MATCH(A2,タスク管理!B:B,0),"ジャンプ")
でうまくリンクを貼ることができました。
 
ありがとうございました。