Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 10 Pro : Excel 2016)
行 列のデータの入れ替え
投稿日時: 20/02/19 17:45:10
投稿者: TI

こんにちは。
 
社員の家族情報の整理をしたいと思っています。
 
元データ
 
社員番号    社員氏名    家族番号    家族氏名    家族生年月日
0001        AAA        1        AAA-AAA        2005/1/1
0001        AAA        2        AAA-BBB        2007/1/5
0001        AAA        3        AAA-CCC        2008/7/7
0002        BBB        1        BBB-DDD        2015/1/1
0003        CCC        1        CCC-EEE        2013/10/1
0003        CCC        2        CCC-FFF        2018/1/10
 
 
加工後データ
社員番号    家族1氏名    家族1生年月日    家族2氏名    家族2生年月日
0001        AAA-AAA        2005/1/1    AAA-BBB        2007/1/5
0002        BBB-DDD        2015/1/1
0003        CCC-EEE        2013/10/1    CCC-FFF        2018/1/10
 
 
というように加工をしたいと考えています。
 
SUMPRODUCTでできるかと思ったのですが、結果は「0」となってしまいます。
 
以下のように記述をしました。
SUMPRODUCT((Sheet1!$A$2:$A$2000=Sheet2!A3)*(Sheet1!E$2:E$2000=1),Sheet1!$C$2:$C$2000)
 
できれば、関数のみで実現をできないかと考えております。
 
アドバイスをお願いします。

回答
投稿日時: 20/02/19 18:28:07
投稿者: んなっと

   A   B   C    D     E F   G    H     I    J     K
1 番号 社員 家番   氏名    生年         1     1    2     2
2   1  AAA   1 AAA-AAA  2005/1/1   番号  氏名1   生年1  氏名2   生年2
3   1  AAA   2 AAA-BBB  2007/1/5    1 AAA-AAA   38353 AAA-BBB  2007/1/5
4   1  AAA   3 AAA-CCC  2008/7/7    2 BBB-DDD  2015/1/1          
5   2  BBB   1 BBB-DDD  2015/1/1    3 CCC-EEE 2013/10/1 CCC-FFF 2018/1/10
6   3  CCC   1 CCC-EEE 2013/10/1                         
7   3  CCC   2 CCC-FFF 2018/1/10                         
 
H3
=IFERROR(IF(INDEX($A:$A,MATCH($G3,$A:$A,0)+H$1-1)=$G3,INDEX($D:$D,MATCH($G3,$A:$A,0)+H$1-1),""),"")
I3
=IFERROR(IF(INDEX($A:$A,MATCH($G3,$A:$A,0)+I$1-1)=$G3,INDEX($E:$E,MATCH($G3,$A:$A,0)+I$1-1),""),"")
I3の表示形式を日付に
→H3:I3選択 右方向・→下方向・↓
 
 
これはこじらせすぎ。
H3
=IFERROR(INDEX($D:$E,AGGREGATE(15,6,ROW($2:$1000)/($A$2:$A$1000=$G3)/($C$2:$C$1000=COUNTIF($H$2:H$2,"*氏名*")),1),1+(COUNTIF(H$2,"*生年*"))),"")

投稿日時: 20/02/20 10:57:36
投稿者: TI

んなっと様
 
ご回答ありがとうございます。
 
ご提示いただいた方法で実現することができました。
 
また、困ったことがありましたら、よろしくお願いします。