PowerPoint (一般・VBA)

PowerPoint 一般・VBAに関する話題を扱うフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 10 Pro : PowerPoint 2016)
大量のPowerPoint資料を一括でPDF化したい
投稿日時: 19/12/26 11:37:22
投稿者: bunbun99

1つのフォルダ内に、大量のPowerPoint資料があります。
 
一括でPDFで保存したいですが、
どのようにすれば良いかご教授頂けたらと思います。
 
 1.1つのフォルダに大量のPowerPointが保存。
 2.一括でPDF保存する。
 
ファイル名を、以下とする。
01_12345.pptx → 01_12345.pdf

回答
投稿日時: 19/12/26 13:47:57
投稿者: sk

引用:
1.1つのフォルダに大量のPowerPointが保存。
2.一括でPDF保存する。
  
ファイル名を、以下とする。
01_12345.pptx → 01_12345.pdf

過去のスレッドより:
https://www.moug.net/faq/viewtopic.php?t=78940
 
「フォルダ内の全てのプレゼンテーションファイルを 1 つずつ開いて
(ごにょごにょしてから)閉じる」処理については、上記スレッドで
例示したコードを応用なさればよいでしょう。
 
(標準モジュール)
-------------------------------------------------------------------
Sub SaveAsPdf()
     
    Dim prs As PowerPoint.Presentation
     
    Dim strFolderPath As String
    Dim strFileName As String
    Dim strPdfFolderPath As String
    Dim strPdfFilePath As String
     
    strFolderPath = "C:\FolderName\"
     
    If Dir(strFolderPath, vbDirectory) = "" Then
        MsgBox "'" & strFolderPath & "'というフォルダが見つかりません。", _
               vbExclamation, _
               "フォルダ参照エラー"
        Exit Sub
    End If
     
    strPdfFolderPath = strFolderPath & "pdf\"
     
    If Dir(strPdfFolderPath, vbDirectory) = "" Then
        MkDir strPdfFolderPath
    End If
     
    strFileName = Dir(strFolderPath & "*.ppt")
     
    If strFileName = "" Then
        MsgBox "'" & strFolderPath & "'フォルダに PowerPoint プレゼンテーションはありません。", _
               vbExclamation, _
               "ファイルなし"
        Exit Sub
    End If
    
    Do Until strFileName = ""
        Set prs = Presentations.Open(strFolderPath & strFileName, True, , False)
        strPdfFilePath = strPdfFolderPath & _
                         Left(strFileName, InStrRev(strFileName, ".")) & "pdf"
        prs.ExportAsFixedFormat strPdfFilePath, ppFixedFormatTypePDF, ppFixedFormatIntentPrint
        prs.Close
        Set prs = Nothing
        strFileName = Dir()
    Loop
     
    Shell "explorer.exe """ & strPdfFolderPath & """", vbMaximizedFocus
     
End Sub
-------------------------------------------------------------------

投稿日時: 19/12/26 23:20:54
投稿者: bunbun99

出来ましたー!!!!希望どおりです!
ありがとうございます。
 
だんだんプログラムの勉強が楽しくなってきました♪