Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 掲示板への投稿には会員登録(無料)が必要です。会員登録がまだの方はこちら
  • 掲示板ご利用上のお願い」に反するご記入はご遠慮ください。
  • Q&A掲示板の使い方はこちらをご覧ください
トピックに返信
質問

 
(Windows 10全般 : Excel 2016)
開始と終了時間を入力して,同一行に複数の印を付ける
投稿日時: 19/10/24 16:04:31
投稿者: 熊

多分無理だとは思うのですが...相談させてください.
  
以下の様に,開始と終了時間を入れて印を付ける方法ですと,
  
=IF(MOD(C$1-$A$2,1)<=MOD($B$2-$A$2,1),"●","")をC2セルから後ろにcopyすると可能なのですが,
  
A    B     C  D  E  F  ・・・
(開始) (終了) 6  7  8  9 ・・・  
7:00    8:00    ●  ● 
  
同一行に複数の開始と終了の●を付けることなどできるのでしょうか.
こんな方法は?と言った発想の転換のヒントなでも聞かせていただけると助かります.
よろしくお願いいたします.

回答
投稿日時: 19/10/24 16:36:38
投稿者: WinArrow
投稿者のウェブサイトに移動

わかりにく数式を掲示するより
文章で説明しましょう。
 
ちょっと見ですが、ガントチャートを作成したいってことでしょうか?
もっと、わかりやすい数式で可能ですよ。
 
C3セル
=IF(AND(TIME(C$2,0,0)>=$A3,TIME(C$2,0,0)<=$B3),"●","")
右へフィルドラッグ
 

回答
投稿日時: 19/10/24 16:43:38
投稿者: bi

開始時間20:00
終了時間02:00
 
などと日をまたぐケースはありますか?

回答
投稿日時: 19/10/24 18:41:02
投稿者: んなっと

=IF(MOD(C$1-$A$2,1)<=MOD($B$2-$A$2,1),"●","")でうまくいくということは、
E1は6ではなくて6:00と入力して、表示形式で[h]にしていますね。
 
   A   B   C   D   E   F   G   H    U   V   W   X
1 開始 終了  開始 終了 6:00 7:00 8:00 9:00  22:00 23:00 24:00 25:00
2 7:00 8:00 23:00 1:00     ●  ●          ●   ●   ●
 
E2
=IF(OR(AND($A2<=E$1,E$1<=$B2+($A2>$B2)),AND($C2<=E$1,E$1<=$D2+($C2>$D2))),"●","")
右方向・→
 
 
※3つ以上の時
 
   A   B   C   D   E   F   H   I   O   P   Q   X   Y   Z
1 開始 終了  開始  終了  開始 終了 7:00 8:00 14:00 15:00 16:00 23:00 24:00 25:00
2 7:00 8:00 14:00 15:00 23:00 1:00  ●  ●   ●   ●      ●   ●   ●
 
G2
=IF(AGGREGATE(14,6,($A2:$E2<=G$1)*($B2:$F2+($A2:$E2>$B2:$F2)>=G$1)/MOD(COLUMN($A2:$E2),2),1)>0,"●","")
右方向・→
 
...誤差が心配。

トピックに返信