Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(指定なし : 指定なし)
昨日教えていただいたのですが、関数 複数条件 分岐
投稿日時: 19/09/18 17:11:53
投稿者: mimi1212

昨日、んなっと様に教えていただいてできたのですが、
https://www.moug.net/faq/viewtopic.php?t=78603
 
引用==============================================
$C$8,$D$8などが間違いです。
 時間の無駄なので、下の式を試してください。
   
テスト作成.xlsxを開いていなくても使えるようにしたい場合の式
E8
 =IFERROR(AGGREGATE(15,6,[テスト作成.xlsx]オーダー!$I$8:$I$46/([テスト作成.xlsx]オーダー!$P$8:$P$46=$D$1)/([テスト作成.xlsx]オーダー!$O$8:$O$46=$E$1)/([テスト作成.xlsx]オーダー!$C$8:$C$46=$C8)/([テスト作成.xlsx]オーダー!$D$8:$D$46=$D8)/([テスト作成.xlsx]オーダー!$H$8:$H$46=E$5),1),"")
右方向・→下方向・↓
================================================
いっぱいいっぱいになっていて、
1点条件があることを失念していました。
 
もし変更有の場合はJ列商品名2とK列数量2の値を取り出し、変更がなければH列の商品名とI列の数量を
取り出したいのです。
 
データが保存されているのはテスト作成というエクセルブックです。
・・・C列 D列 ・・・H列    I列  J列   K列   L列   O列  P列
・・・NO 枝番 ・・・商品名  数量  商品名2 数量2  変更  月   会社名
・・・1号 1  ・・・リンゴ  20   もも   30    有   4   A社
・・・1号 1  ・・・みかん  40                4   A社
・・・1号 2  ・・・もも   50                5   B社
・・・2号 1  ・・・リンゴ  30                5   C社
・・・2号 1  ・・・もも   25                4   A社
・・・2号 2  ・・・なし   60                4   A社
  
  
例)
D1 A社 ←会社名を入力  
E1 4  ←月を入力 
C列 NOを入力    
D列 枝番を入力
 
表に値を代入したいのです
 
 行     C列 D列  E列   F列  G列  H列   I列
5行目・・・ NO  枝番 リンゴ  みかん もも ブドウ  なし
 ・
 ・
8行目・・・1号  1       40   30(変更有の値)
9行目・・・2号  2                  60
 
一度にお聞きしたらよかったのですが、大変申し訳ありません。
どなたかよろしくお願いいたしま。          

回答
投稿日時: 19/09/18 17:47:11
投稿者: んなっと

右のほうあいている列(下の例ではR:S列)に変更無しと有りをまとめてしまって
 
     H   I    J   K   L     R   S
 7 商品名 数量 商品名2 数量2 変更  商品  数
 8 リンゴ  20   もも   30  有   もも  30
 9 みかん  40             みかん  40
10  もも  50              もも  50
11 リンゴ  30             リンゴ  30
12  もも  25              もも  25
13 ブドウ  80             ブドウ  80
14  なし  60              なし  60
 
R8
=IF($L8="",H8,J8)
右方向・→下方向・↓
 
 
H:I列のかわりにR:S列を参照しましょう。
 
   C   D    E    F   G    H   I
1    A社    4              
2                        
3                        
4                        
5  NO 枝番 リンゴ みかん もも ブドウ なし
6                        
7                        
8 1号   1       40  30       
9 2号   2              80  60
 
E8
=IFERROR(AGGREGATE(15,6,[テスト作成.xlsx]オーダー!$S$8:$S$46/([テスト作成.xlsx]オーダー!$P$8:$P$46=$D$1)/([テスト作成.xlsx]オーダー!$O$8:$O$46=$E$1)/([テスト作成.xlsx]オーダー!$C$8:$C$46=$C8)/([テスト作成.xlsx]オーダー!$D$8:$D$46=$D8)/([テスト作成.xlsx]オーダー!$R$8:$R$46=E$5),1),"")
右方向・→下方向・↓
 
※ピボットテーブルもおすすめです。検索して勉強してみてください。
「商品」を「列」にドラッグしてスライサーを挿入。

投稿日時: 19/09/19 14:56:31
投稿者: mimi1212

んなっと様
ご親切にありがとうございます。
ピボットテーブルについても勉強してみます。
 
お世話になり本当にありがとうございました。