Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 10 Pro : Excel 2016)
SUMPRODUCTで切り替え
投稿日時: 19/01/31 16:37:36
投稿者: 純

よろしくお願いします。
 

	CW	CZ	DA	DB	FC	FE
3		女性1	キッズ	女性2	男性	是正店
4		201901	201901	201901	201906	
5	部コード	計画	計画	計画	計画	
6	1	157	170	294	179	
7	3	130	150	170	130	1
8	4	40	43	74	45	
9	1	141	153	265	161	1
10	2	23	24	42	26	
11	1	117	127	220	134	

 
シート2に上記のような元データがあります。
 
範囲に名前を付けています。
 
CW6:CW602    計画A
CZ3:FC3        計画D
CZ4:FC4        計画E
CZ6:FC602    計画範囲
FE6:FE602    計画G
        
FE列の1は是正店、1でなければ通常店    
 
シート1で
 
	C	H	J
1		201901	
2			通常店
3			
4			
5		女性	
6			
7			
8			
9	部コード		
10	1	0	
11	2	0	
12	3	0	
13	4	0	

 
条件が複数あるのですが、1つ目は
シート1のH5セルでプルダウンで以下の項目を切替可能にしています。
女性
女性1
女性2
キッズ
男性
 
その中で「女性」を選択した時は「女性1」「女性2」を合算させたくて
 
もう一つの条件は、シート1のJ2セルで、こちらも是正店と通常店がプルダウンで選択できるようにしています。
 
H10セルで以下の式までは作成したのですが、女性の合算と通常・是正の切り替えをどのようにしたらいいのかわからないので教えていただきたいと思います。
 
=SUMPRODUCT((計画A=$C10)*(計画D=$H$5)*(計画E=H$1)*(計画G=1)*(計画範囲))
 
どうぞよろしくお願いいたします。

回答
投稿日時: 19/01/31 18:12:00
投稿者: んなっと

ほとんど試していないので、間違っているかもしれません。
 
H10
=SUMPRODUCT((計画A=$C10)*(LEFT(計画D,LEN($H$5))=$H$5)*(計画E=H$1)*((J$2="是正店")*(計画G=1)+(J$2<>"是正店")*(計画G<>1))*(計画範囲))
 
 
※シート2のFE6:FE602が1と空白セルだけであれば、
H10
=SUMPRODUCT((計画A=$C10)*(LEFT(計画D,LEN($H$5))=$H$5)*(計画E=H$1)*(計画G-(J$2="是正店")=0)*(計画範囲))

投稿日時: 19/01/31 23:25:29
投稿者: 純

んなっと さま
 
いつもありがとうございます。
 
教えていただいた式で無事解決出来ました。
 
IF関数を組み込む事しか考えていませんでしたがSUMPRODUCTだけで解決できて嬉しいです。
 
本当にありがとうございました。